
theorem Th47:
  for A, B being Ordinal-Sequence, b being Ordinal
  holds b -exponent (A ^ B) = (b -exponent A) ^ (b -exponent B)
proof
  let A, B be Ordinal-Sequence, b be Ordinal;
  A1: dom(b -exponent (A ^ B)) = dom(A^B) by Def1
    .= dom A +^ dom B by ORDINAL4:def 1
    .= dom A +^ dom(b -exponent B) by Def1
    .= dom(b -exponent A) +^ dom(b -exponent B) by Def1
    .= dom((b -exponent A) ^ (b -exponent B)) by ORDINAL4:def 1;
  now
    let x be object;
    assume x in dom(b -exponent (A ^ B));
    then A2: x in dom(A^B) by Def1;
    then A3: (b -exponent (A ^ B)).x = b -exponent ((A^B).x) by Def1;
    reconsider c = x as Ordinal by A2;
    c in dom A or (dom A c= c & c -^ dom A in dom B)
    proof
      assume not c in dom A;
      hence A4: dom A c= c by ORDINAL1:16;
      c in dom A +^ dom B by A2, ORDINAL4:def 1;
      then c -^ dom A in dom A +^ dom B -^ dom A by A4, ORDINAL3:53;
      hence thesis by ORDINAL3:52;
    end;
    then per cases;
    suppose A5: c in dom A;
      then A6: c in dom(b -exponent A) by Def1;
      (A^B).x = A.x by A5, ORDINAL4:def 1;
      hence (b -exponent (A ^ B)).x = (b -exponent A).x by A3, A5, Def1
        .= ((b -exponent A) ^ (b -exponent B)).x by A6, ORDINAL4:def 1;
    end;
    suppose A7: dom A c= c & c -^ dom A in dom B;
      then A8: c -^ dom A in dom(b -exponent B) by Def1;
      (A^B).x = (A^B).(dom A +^ (c -^ dom A)) by A7, ORDINAL3:def 5
        .= B.(c -^ dom A) by A7, ORDINAL4:def 1;
      hence (b -exponent (A ^ B)).x = (b -exponent B).(c -^ dom A)
          by A3, A7, Def1
        .= ((b -exponent A) ^ (b -exponent B)).
          (dom(b -exponent A) +^ (c -^ dom A)) by A8, ORDINAL4:def 1
        .= ((b -exponent A) ^ (b -exponent B)).(dom A +^ (c -^ dom A))
          by Def1
        .= ((b -exponent A) ^ (b -exponent B)).x by A7, ORDINAL3:def 5;
    end;
  end;
  hence thesis by A1, FUNCT_1:2;
end;
