reserve A,O for non empty set,
  R for Order of A,
  Ol for Equivalence_Relation of O,
  f for Function of O,A*,
  g for Function of O,A;
reserve S for OverloadedRSSign;
reserve S0 for non empty non void ManySortedSign;
reserve S for non empty Poset;
reserve s1,s2 for Element of S;
reserve w1,w2 for Element of (the carrier of S)*;
reserve S for OrderSortedSign;
reserve o,o1,o2 for OperSymbol of S;
reserve w1 for Element of (the carrier of S)*;
reserve SM for monotone OrderSortedSign,
  o,o1,o2 for OperSymbol of SM,
  w1 for Element of (the carrier of SM)*;
reserve SR for regular monotone OrderSortedSign,
  o,o1,o3,o4 for OperSymbol of SR,
  w1 for Element of (the carrier of SR)*;
reserve R for non empty Poset;
reserve z for non empty set;
reserve s1,s2 for SortSymbol of S,
  o,o1,o2,o3 for OperSymbol of S,
  w1,w2 for Element of (the carrier of S)*;
reserve CH for ManySortedFunction of ConstOSSet(S,z)# * the Arity of S,
  ConstOSSet(S,z) * the ResultSort of S;
reserve A for OSAlgebra of S;
reserve M for MSAlgebra over S0;
reserve A for OSAlgebra of S;
reserve op1,op2 for OperSymbol of S;

theorem Th34:
  for SR being regular monotone OrderSortedSign, op1,op2 being
OperSymbol of SR, w being Element of (the carrier of SR)* st op1 ~= op2 & w <=
  the_arity_of op1 & w <= the_arity_of op2 holds LBound(op1,w) = LBound(op2,w)
proof
  let SR be regular monotone OrderSortedSign, op1,op2 be OperSymbol of SR, w
  be Element of (the carrier of SR)* such that
A1: op1 ~= op2 and
A2: w <= the_arity_of op1 and
A3: w <= the_arity_of op2;
  set Lo1 = LBound(op1,w), Lo2 = LBound(op2,w);
A4: LBound(op1,w) has_least_args_for op1,w by A2,Def14;
  then
A5: op1 ~= Lo1;
A6: LBound(op2,w) has_least_args_for op2,w by A3,Def14;
  then
A7: for o2 being OperSymbol of SR st op2 ~= o2 & w <= the_arity_of o2 holds
  the_arity_of Lo2 <= the_arity_of o2;
  op2 ~= Lo2 by A6;
  then
A8: op1 ~= Lo2 by A1,Th2;
  then
A9: Lo1 ~= Lo2 by A5,Th2;
  w <= the_arity_of Lo1 by A4;
  then
A10: the_arity_of Lo2 <= the_arity_of Lo1 by A1,A5,A7,Th2;
  then
A11: the_result_sort_of Lo2 <= the_result_sort_of Lo1 by A9,Def7;
  w <= the_arity_of Lo2 by A6;
  then
A12: the_arity_of Lo1 <= the_arity_of Lo2 by A4,A8;
  then
A13: the_arity_of Lo1 = the_arity_of Lo2 by A10,Th6;
  the_result_sort_of Lo1 <= the_result_sort_of Lo2 by A9,A12,Def7;
  then the_result_sort_of Lo1 = the_result_sort_of Lo2 by A11,ORDERS_2:2;
  hence thesis by A9,A13,Def3;
end;
