reserve L for Ortholattice,
  a, b, c for Element of L;

theorem Th34:
  L is orthomodular iff for a,b being Element of L st b [= a holds
  a "/\" (a` "\/" b) = b
proof
  thus L is orthomodular implies for a,b being Element of L st b [= a holds a
  "/\" (a` "\/" b) = b
  proof
    assume
A1: L is orthomodular;
    let a,b be Element of L;
    assume b [= a;
    then a` [= b` by Th4;
    then b` = a` "\/" (a`` "/\" b`) by A1
      .= a` "\/" (a "/\" b`) by ROBBINS3:def 6
      .= a` "\/" (a` "\/" b``)` by ROBBINS1:def 23
      .= a` "\/" (a` "\/" b)` by ROBBINS3:def 6
      .= (a` "\/" (a` "\/" b)`)`` by ROBBINS3:def 6
      .= (a "/\" (a` "\/" b))` by ROBBINS1:def 23;
    then b``= (a "/\" (a` "\/" b)) by ROBBINS3:def 6;
    hence thesis by ROBBINS3:def 6;
  end;
  assume
A2: for a,b being Element of L st b [= a holds a "/\" (a` "\/" b) = b;
  let a,b be Element of L;
  assume a [= b;
  then b` [= a` by Th4;
  then b` = a`"/\"(a``"\/"b`) by A2
    .= a`"/\"(a``"\/"b`)`` by ROBBINS3:def 6
    .= a` "/\" (a` "/\" b)` by ROBBINS1:def 23
    .= (a`` "\/"(a` "/\" b)``)` by ROBBINS1:def 23
    .= (a "\/" (a` "/\" b)``)` by ROBBINS3:def 6
    .= (a "\/" (a` "/\" b))` by ROBBINS3:def 6;
  then b`` = (a "\/" (a` "/\" b)) by ROBBINS3:def 6;
  hence b = a "\/" (a` "/\" b) by ROBBINS3:def 6;
end;
