reserve i,j,k,l,m,n for Nat,
  D for non empty set,
  f for FinSequence of D;
reserve X for compact Subset of TOP-REAL 2;
reserve r for Real;

theorem
  S-bound R^2-unit_square = 0
proof
  set X = R^2-unit_square;
  reconsider Z = (proj2|X).:the carrier of ((TOP-REAL 2)|X) as Subset of REAL;
A1: X = [#]((TOP-REAL 2)|X) by PRE_TOPC:def 5
    .= the carrier of ((TOP-REAL 2)|X);
A2: for q be Real st for p be Real st p in Z holds p >= q
  holds 0 >= q
  proof
    let q be Real such that
A3: for p be Real st p in Z holds p >= q;
    |[1,0]| in LSeg(|[ 1,0 ]|, |[ 1,1 ]|) by RLTOPSP1:68;
    then |[1,0]| in LSeg(|[ 0,0 ]|, |[ 1,0 ]|) \/ LSeg(|[ 1,0 ]|, |[ 1,1 ]|)
    by XBOOLE_0:def 3;
    then
A4: |[1,0]| in X by XBOOLE_0:def 3;
    then (proj2|X). |[1,0]| = |[1,0]|`2 by PSCOMP_1:23
      .= 0 by EUCLID:52;
    hence thesis by A1,A3,A4,FUNCT_2:35;
  end;
  for p be Real st p in Z holds p >= 0
  proof
    let p be Real;
    assume p in Z;
    then consider p0 being object such that
A5: p0 in the carrier of (TOP-REAL 2)|X and
    p0 in the carrier of (TOP-REAL 2)|X and
A6: p = (proj2|X).p0 by FUNCT_2:64;
    reconsider p0 as Point of TOP-REAL 2 by A1,A5;
    ex q being Point of TOP-REAL 2 st p0 = q & (q`1 = 0 & q`2 <= 1 & q`2
>= 0 or q`1 <= 1 & q`1 >= 0 & q`2 = 1 or q`1 <= 1 & q`1 >= 0 & q`2 = 0 or q`1 =
    1 & q`2 <= 1 & q`2 >= 0) by A1,A5,TOPREAL1:14;
    hence thesis by A1,A5,A6,PSCOMP_1:23;
  end;
  hence thesis by A2,SEQ_4:44;
end;
