reserve i,j,k,n,m for Nat;
reserve p,q for Point of TOP-REAL 2;
reserve G for Go-board;
reserve C for Subset of TOP-REAL 2;

theorem Th34:
  for f being rectangular special_circular_sequence holds SpStSeq L~f = f
proof
  let f be rectangular special_circular_sequence;
  set C = L~f, g = SpStSeq C;
  consider D being non vertical non horizontal non empty compact Subset of
  TOP-REAL 2 such that
A1: f = SpStSeq D by SPRECT_1:def 2;
A2: 5 = len f by SPRECT_1:82;
  SpStSeq L~f = <*NW-corner L~f,NE-corner L~f,SE-corner L~f*>^ <*SW-corner
  L~f,NW-corner L~f*> by SPRECT_1:def 1;
  then
A3: len g = len<*NW-corner L~f,NE-corner L~f,SE-corner L~f*> +len<*SW-corner
  L~f,NW-corner L~f*> by FINSEQ_1:22
    .= 3+len<*SW-corner L~f,NW-corner L~f*> by FINSEQ_1:45
    .= 3+2 by FINSEQ_1:44;
A4: for i being Nat st i in dom f holds f/.i = g/.i
  proof
    let i be Nat;
    assume
A5: i in dom f;
    then
A6: 0 <> i by FINSEQ_3:25;
A7: i <= len f by A5,FINSEQ_3:25;
A8: f/.1 = W-max C by SPRECT_1:83
      .= NW-corner D by A1,SPRECT_1:75
      .= NW-corner C by A1,SPRECT_1:62
      .= g/.1 by SPRECT_1:35;
    i <= 5 by A2,A7;
    then i = 0 or ... or i = 5;
    then per cases by A6;
    suppose
      i = 1;
      hence thesis by A8;
    end;
    suppose
A9:   i = 2;
      hence f/.i = E-max C by SPRECT_1:84
        .= NE-corner D by A1,SPRECT_1:79
        .= NE-corner C by A1,SPRECT_1:63
        .= g/.i by A9,SPRECT_1:36;
    end;
    suppose
A10:  i = 3;
      hence f/.i = E-min C by SPRECT_1:85
        .= SE-corner D by A1,SPRECT_1:78
        .= SE-corner C by A1,SPRECT_1:65
        .= g/.i by A10,SPRECT_1:37;
    end;
    suppose
A11:  i = 4;
      hence f/.i = W-min C by SPRECT_1:86
        .= SW-corner D by A1,SPRECT_1:74
        .= SW-corner C by A1,SPRECT_1:64
        .= g/.i by A11,SPRECT_1:38;
    end;
    suppose
A12:  i = 5;
      hence f/.i = f/.1 by A2,FINSEQ_6:def 1
        .= g/.i by A3,A8,A12,FINSEQ_6:def 1;
    end;
  end;
  dom f = dom g by A2,A3,FINSEQ_3:29;
  hence thesis by A4,FINSEQ_5:12;
end;
