reserve T for non empty TopSpace,
  A, B for Subset of T,
  F, G for Subset-Family of T;

theorem Th34:
  for F, G being set st F <> {} & G <> {} holds meet F /\ meet G =
  meet INTERSECTION(F,G)
proof
  let F, G be set;
  assume that
A1: F <> {} and
A2: G <> {};
  consider y being object such that
A3: y in F by A1,XBOOLE_0:def 1;
  reconsider y as set by TARSKI:1;
  consider z being object such that
A4: z in G by A2,XBOOLE_0:def 1;
  reconsider z as set by TARSKI:1;
A5: meet INTERSECTION(F,G) c= meet F /\ meet G
  proof
    let x be object such that
A6: x in meet INTERSECTION(F,G);
    for Z be set st Z in G holds x in Z
    proof
      let Z be set;
      assume Z in G;
      then y /\ Z in INTERSECTION(F,G) by A3,SETFAM_1:def 5;
      then x in y /\ Z by A6,SETFAM_1:def 1;
      hence thesis by XBOOLE_0:def 4;
    end;
    then
A7: x in meet G by A2,SETFAM_1:def 1;
    for Z be set st Z in F holds x in Z
    proof
      let Z be set;
      assume Z in F;
      then Z /\ z in INTERSECTION(F,G) by A4,SETFAM_1:def 5;
      then x in Z /\ z by A6,SETFAM_1:def 1;
      hence thesis by XBOOLE_0:def 4;
    end;
    then x in meet F by A1,SETFAM_1:def 1;
    hence thesis by A7,XBOOLE_0:def 4;
  end;
A8: y /\ z in INTERSECTION(F,G) by A3,A4,SETFAM_1:def 5;
  meet F /\ meet G c= meet INTERSECTION (F,G)
  proof
    let x be object;
    assume x in meet F /\ meet G;
    then
A9: x in meet F & x in meet G by XBOOLE_0:def 4;
    for Z be set st Z in INTERSECTION(F,G) holds x in Z
    proof
      let Z be set;
      assume Z in INTERSECTION(F,G);
      then consider Z1,Z2 be set such that
A10:  Z1 in F & Z2 in G and
A11:  Z = Z1 /\ Z2 by SETFAM_1:def 5;
      x in Z1 & x in Z2 by A9,A10,SETFAM_1:def 1;
      hence thesis by A11,XBOOLE_0:def 4;
    end;
    hence thesis by A8,SETFAM_1:def 1;
  end;
  hence thesis by A5;
end;
