reserve x,y,z,a,b,c,X,X1,X2,Y,Z for set,
  W,W1,W2 for Tree,
  w,w9 for Element of W,
  f for Function,
  D,D9 for non empty set,
  i,k,k1,k2,l,m,n for Nat,
  v,v1,v2 for FinSequence,
  p,q,r,r1,r2 for FinSequence of NAT;
reserve C for Chain of W,
  B for Branch of W;
reserve T,T1,T2 for DecoratedTree;

theorem Th34:
  (for x st x in X holds x is Function) & X is c=-linear implies
  union X is Relation-like Function-like
proof
  assume that
A1: for x st x in X holds x is Function and
A2: X is c=-linear;
  thus for a being object holds a in union X implies
    ex b,c being object st [b,c] = a
  proof let a be object;
    assume a in union X;
    then consider x be set such that
A3: a in x and
A4: x in X by TARSKI:def 4;
    reconsider x as Function by A1,A4;
 x = x;
    hence thesis by A3,RELAT_1:def 1;
  end;
  let a,b,c be object;
  assume that
A5: [a,b] in union X and
A6: [a,c] in union X;
  consider x be set such that
A7: [a,b] in x and
A8: x in X by A5,TARSKI:def 4;
  consider y be set such that
A9: [a,c] in y and
A10: y in X by A6,TARSKI:def 4;
  reconsider x as Function by A1,A8;
  reconsider y as Function by A1,A10;
 x,y are_c=-comparable by A2,A8,A10;
then  x c= y or y c= x;
  hence thesis by A7,A9,FUNCT_1:def 1;
end;
