reserve
  S for (4,1) integer bool-correct non empty non void BoolSignature,
  X for non-empty ManySortedSet of the carrier of S,
  T for vf-free integer all_vars_including inheriting_operations free_in_itself
  (X,S)-terms VarMSAlgebra over S,
  C for (4,1) integer bool-correct non-empty image of T,
  G for basic GeneratorSystem over S,X,T,
  A for IfWhileAlgebra of the generators of G,
  I for integer SortSymbol of S,
  x,y,z,m for pure (Element of (the generators of G).I),
  b for pure (Element of (the generators of G).the bool-sort of S),
  t,t1,t2 for Element of T,I,
  P for Algorithm of A,
  s,s1,s2 for Element of C-States(the generators of G);
reserve
  f for ExecutionFunction of A, C-States(the generators of G),
  (\falseC)-States(the generators of G, b);
reserve u for ManySortedFunction of FreeGen T, the Sorts of C;

theorem
  for t1,t2 being Element of T, the bool-sort of S holds
  t1\andt2 value_at(C,s) = (t1 value_at(C,s))\and(t2 value_at(C,s))
  proof
    let t1,t2 be Element of T, the bool-sort of S;
    s is ManySortedFunction of the generators of G, the Sorts of C
    by AOFA_A00:48;
    then consider f being ManySortedFunction of T,C such that
A1: f is_homomorphism T,C & s = f||(the generators of G) by AOFA_A00:def 19;
A2: t1 value_at(C,s) = f.(the bool-sort of S).t1 by A1,Th29;
A3: t1\andt2 value_at(C,s) = f.(the bool-sort of S).(t1\andt2) by A1,Th29;
    set o = In((the connectives of S).3, the carrier' of S);
A4: the_arity_of o = <*the bool-sort of S,the bool-sort of S*> &
    the_result_sort_of o = the bool-sort of S by Th13;
    then Args(o,T) = product <*(the Sorts of T).the bool-sort of S,
    (the Sorts of T).the bool-sort of S*> by Th23;
    then reconsider p = <*t1,t2*> as Element of Args(o,T) by FINSEQ_3:124;
    thus (t1\andt2) value_at(C,s) = Den(o,C).(f#p)
    by A1,A3,A4
    .= Den(o,C).<*f.(the bool-sort of S).t1,f.(the bool-sort of S).t2*>
    by A4,Th26
    .= (t1 value_at(C,s))\and(t2 value_at(C,s)) by A2,A1,Th29;
  end;
