
theorem Th32:
  for R being connected non empty Poset,
  x,y being Element of Fin the carrier of R
  holds [x,y] in union rng FinOrd-Approx R iff x = {} or
  x<>{} & y<>{} & PosetMax x <> PosetMax y &
  [PosetMax x,PosetMax y] in the InternalRel of R or
  x<>{} & y<>{} & PosetMax x = PosetMax y &
  [x\{PosetMax x},y\{PosetMax y}] in union rng FinOrd-Approx R
proof
  let R be connected non empty Poset,
  x,y be Element of Fin the carrier of R;
  set IR = the InternalRel of R, CR = the carrier of R;
  set FOAR = FinOrd-Approx R;
A1: FOAR.0 = {[a,b] where a,b is Element of Fin CR : a = {} or
  (a<>{} & b<>{} & PosetMax a <> PosetMax b &
  [PosetMax a, PosetMax b] in IR)} by Def14;
A2: dom FOAR = NAT by Def14;
  hereby
    assume [x,y] in union rng FOAR;
    then consider Y being set such that
A3: [x,y] in Y and
A4: Y in rng FOAR by TARSKI:def 4;
    consider n being object such that
A5: n in dom FOAR and
A6: Y = FOAR.n by A4,FUNCT_1:def 3;
    reconsider n as Element of NAT by A5;
    per cases;
    suppose n = 0;
      then consider a,b being Element of Fin CR such that
A7:   [x,y] = [a,b] and
A8:   a = {} or a <> {} & b <> {} & PosetMax a <> PosetMax b &
      [PosetMax a, PosetMax b] in IR by A1,A3,A6;
      x = a by A7,XTUPLE_0:1;
      hence x = {} or x <> {} & y <> {} & PosetMax x <> PosetMax y &
      [PosetMax x,PosetMax y] in IR or
      x <> {} & y <> {} & PosetMax x = PosetMax y &
      [x\{PosetMax x}, y\{PosetMax y}] in union rng FOAR by A7,A8,XTUPLE_0:1;
    end;
    suppose n > 0;
      then
A9:   n-1 is Element of NAT by NAT_1:20;
      then FOAR.(n-1+1) = {[a,b] where a,b is Element of Fin CR : a<>{} &
      b <> {} & PosetMax a = PosetMax b &
      [a\{PosetMax a},b\{PosetMax b}] in FOAR.(n-1)} by Def14;
      then consider a,b being Element of Fin CR such that
A10:  [x,y] = [a,b] and
      a<>{} and
A11:  b<>{} and
A12:  PosetMax a = PosetMax b and
A13:  [a\{PosetMax a},b\{PosetMax b}] in FOAR.(n-1) by A3,A6;
A14:  x = a by A10,XTUPLE_0:1;
A15:  y = b by A10,XTUPLE_0:1;
      FOAR.(n-1) in rng FOAR by A2,A9,FUNCT_1:def 3;
      hence x = {} or x <> {} & y <> {} & PosetMax x <> PosetMax y &
      [PosetMax x, PosetMax y] in IR or
      x <> {} & y <> {} & PosetMax x = PosetMax y &
      [x \ {PosetMax x}, y \ {PosetMax y}] in union rng FOAR
      by A11,A12,A13,A14,A15,TARSKI:def 4;
    end;
  end;
  assume
A16: x = {} or x <> {} & y <> {} & PosetMax x <> PosetMax y &
  [PosetMax x, PosetMax y] in IR or
  x <> {} & y <> {} & PosetMax x = PosetMax y &
  [x\{PosetMax x}, y\{PosetMax y}] in union rng FOAR;
  per cases by A16;
  suppose x = {};
    then
A17: [x,y] in FOAR.0 by A1;
    FOAR.0 in rng FOAR by A2,FUNCT_1:def 3;
    hence thesis by A17,TARSKI:def 4;
  end;
  suppose x <> {} & y <> {} & PosetMax x <> PosetMax y &
    [PosetMax x, PosetMax y] in IR;
    then
A18: [x,y] in FOAR.0 by A1;
    FOAR.0 in rng FOAR by A2,FUNCT_1:def 3;
    hence thesis by A18,TARSKI:def 4;
  end;
  suppose
A19: x<>{} & y<>{} & PosetMax x = PosetMax y &
    [x\{PosetMax x}, y\{PosetMax y}] in union rng FOAR;
    set NEXTXY = [x\{PosetMax x}, y\{PosetMax y}];
    consider Y being set such that
A20: NEXTXY in Y and
A21: Y in rng FinOrd-Approx R by A19,TARSKI:def 4;
    consider n being object such that
A22: n in dom FOAR and
A23: Y = FOAR.n by A21,FUNCT_1:def 3;
    reconsider n as Nat by A22;
    FOAR.(n+1) = {[a,b] where a,b is Element of Fin CR: a<>{} & b<>{}&
    PosetMax a = PosetMax b & [a\{PosetMax a}, b\{PosetMax b}] in FOAR.n}
    by Def14;
    then
A24: [x,y] in FOAR.(n+1) by A19,A20,A23;
    FOAR.(n+1) in rng FOAR by A2,FUNCT_1:def 3;
    hence thesis by A24,TARSKI:def 4;
  end;
end;
