reserve Y for non empty set;

theorem
  for a,b being Function of Y,BOOLEAN holds 'not'( a 'imp' 'not' b
  ) 'imp' (a '&' b)=I_el(Y)
proof
  let a,b be Function of Y,BOOLEAN;
  for x being Element of Y holds ('not'( a 'imp' 'not' b) 'imp' (a '&' b))
  .x=TRUE
  proof
    let x be Element of Y;
    ('not'( a 'imp' 'not' b) 'imp' (a '&' b)).x ='not' ('not'( a 'imp'
    'not' b)).x 'or' (a '&' b).x by BVFUNC_1:def 8
      .='not' 'not' (a 'imp' 'not' b).x 'or' (a '&' b).x by MARGREL1:def 19
      .='not' 'not' (a 'imp' 'not' b).x 'or' (a.x '&' b.x) by
MARGREL1:def 20
      .=('not' a.x 'or' ('not' b).x) 'or' (a.x '&' b.x) by BVFUNC_1:def 8
      .=('not' a.x 'or' 'not' b.x) 'or' (a.x '&' b.x) by
MARGREL1:def 19
      .=(('not' a.x 'or' 'not' b.x) 'or' a.x) '&' (('not' a.x 'or'
    'not' b.x) 'or' b.x) by XBOOLEAN:9
      .=(('not' a.x 'or' a.x) 'or' 'not' b.x) '&' ('not' a.x 'or' (
    'not' b.x 'or' b.x))
      .=(TRUE 'or' 'not' b.x) '&' ('not' a.x 'or' ('not' b.x 'or' b.
    x)) by XBOOLEAN:102
      .=TRUE '&' ('not' a.x 'or' TRUE) by XBOOLEAN:102
      .=TRUE;
    hence thesis;
  end;
  hence thesis by BVFUNC_1:def 11;
end;
