reserve h for non-zero 0-convergent Real_Sequence;
reserve c for constant Real_Sequence;

theorem Th35:
for f be PartFunc of REAL,REAL, x0 be Real st f is_Rcontinuous_in x0 holds
 f|(right_closed_halfline x0) is_continuous_in x0
proof
    let f be PartFunc of REAL,REAL, x0 be Real;
    assume A1: f is_Rcontinuous_in x0; then
A2: x0 in dom f &
    for e be Real st 0<e ex d be Real st 0 < d &
     for x be Real st x in dom f & x0 < x & x < x0+d holds
      |. f.x - f.x0 .| < e by Th28;

    set f1=f|(right_closed_halfline x0);
    for e be Real st 0<e ex d be Real st 0<d & for x be Real st
     x in dom f1 & |. x-x0 .| < d holds |. f1.x - f1.x0 .| < e
    proof
     let e be Real;
     assume
A3:   0<e; then
     consider d be Real such that
A4:   0 < d and
A5:   for x be Real st x in dom f & x0 < x & x < x0+d holds
       |. f.x - f.x0 .| < e by A1,Th28;
     take d;
     thus 0 < d by A4;
     thus for x be Real st x in dom f1 & |. x-x0 .| < d
      holds |. f1.x - f1.x0 .| < e
     proof
      let x be Real;
      assume that
A6:    x in dom f1 and
A7:    |. x-x0 .| < d;
      dom f1 = dom f /\ right_closed_halfline x0 by RELAT_1:61; then
A8:   x in dom f & x in right_closed_halfline x0 by A6,XBOOLE_0:def 4; then
      x in [.x0,+infty.[ by LIMFUNC1:def 2; then
A9:   x0 <= x by XXREAL_1:236;
      per cases;
      suppose x = x0;
       hence |. f1.x - f1.x0 .| < e by A3,COMPLEX1:44;
      end;
      suppose x <> x0; then
A10:    x0 < x by A9,XXREAL_0:1; then
       x-x0 >0 by XREAL_1:50; then
       x-x0 < d by A7,ABSVALUE:def 1; then
A11:    x < x0+d by XREAL_1:19;
       x0 in [.x0,+infty.[ by XXREAL_1:236; then
       x0 in right_closed_halfline x0 by LIMFUNC1:def 2; then
       f1.x = f.x & f1.x0 = f.x0 by A6,A2,RELAT_1:57,FUNCT_1:47;
       hence |. f1.x - f1.x0 .| < e by A5,A8,A10,A11;
      end;
     end;
    end;
    hence thesis by FCONT_1:3;
end;
