
theorem
  for n being Nat st n >= 2 & n is even holds
  Lucas (n+1) = [/ tau * Lucas n - 1 \]
  proof
    let n be Nat;
    set tn = tau_bar to_power n;
    assume A1: n >= 2 & n is even;
A2: Lucas (n+1) = tau to_power (n+1) + tau_bar to_power (n+1) by FIB_NUM3:21;
A3: tau * Lucas n = tau * (tau to_power n + tau_bar to_power n) by FIB_NUM3:21
    .= tau * tau to_power n + tau * tau_bar to_power n
    .= tau to_power 1 * tau to_power n + tau * tau_bar to_power n
    .= tau to_power (n+1) + tau * tn by Th2;
A4: tau * Lucas n - 1 <= Lucas (n+1)
    proof
      tau * tn - 1 <= tau_bar to_power (n+1)
      proof
A5:     tn > 0 by Th6,A1;
        tn <= 1 / sqrt 5 by Th16,A1; then
        1 / tn >= 1 / (1/sqrt 5) by Th6,A1,XREAL_1:118; then
        1 / tn >= sqrt 5 by XCMPLX_1:52; then
        (1 / tn) * 2 >= (sqrt 5) * 2 by XREAL_1:64; then
        (1 / tn) * 2 + 1 >= 2 * sqrt 5 + 1 by XREAL_1:6; then
        (1 / tn) * 2 + 1 - sqrt 5 >= 2 * sqrt 5 + 1 - sqrt 5
          by XREAL_1:13; then
        ((1 / tn) * 2 + (1 - sqrt 5)) / 2 >= (sqrt 5 + 1)/2 by XREAL_1:72; then
        ((1 / tn) + tau_bar) * tn >=
        tau * tn by A5,FIB_NUM:def 1,def 2,XREAL_1:64; then
        (1 / tn) * tn + tau_bar * tn >= tau * tn; then
        (1 / tn) * tn + tau_bar to_power 1 * tn >= tau * tn; then
        1 + tau_bar to_power 1 * tn >= tau * tn by A5,XCMPLX_1:87; then
        1 + tau_bar to_power (n+1) >= tau*tn by Th2; then
        1 + tau_bar to_power (n+1) - 1 >= tau * tn - 1 by XREAL_1:9;
        hence thesis;
      end; then
      tau to_power (n+1) + (tau * tn - 1) <=
      tau to_power (n+1) + tau_bar to_power (n+1) by XREAL_1:6;
      hence thesis by A3,FIB_NUM3:21;
    end;
    tau * Lucas n - 1 + 1 > Lucas (n+1)
    proof
      tn = (- tau_bar) to_power n by A1,Th3; then
   tn > 0 by POWER:34;
      then tau * tn > tau_bar * tn by XREAL_1:68; then
      tau * tn > tau_bar to_power 1 * tn; then
      tau * tn > tau_bar to_power (n+1) by Th2;
      hence thesis by A2,A3,XREAL_1:6;
    end;
    hence thesis by A4,INT_1:def 7;
  end;
