reserve FT for non empty RelStr,
  A,B,C for Subset of FT;

theorem Th34:
  for A,C being Subset of FT st FT is symmetric & C is connected &
  C c= A & A c=C^b holds A is connected
proof
  let A,C be Subset of FT;
  assume that
A1: FT is symmetric and
A2: C is connected and
A3: C c= A and
A4: A c= C^b;
  let P2,Q2 be Subset of FT;
  assume that
A5: A=P2\/Q2 and
A6: P2<>{} and
A7: Q2<>{} and
A8: P2 misses Q2;
  assume
A9: not thesis;
  set x2 = the Element of Q2;
A10: x2 in Q2 by A7;
  Q2 c= Q2 \/P2 by XBOOLE_1:7;
  then Q2 c= C^b by A4,A5;
  then x2 in C^b by A10;
  then consider z2 being Element of FT such that
A11: z2=x2 and
A12: U_FT z2 meets C;
  set y3 = the Element of U_FT z2 /\ C;
A13: U_FT z2 /\ C <> {} by A12;
  then y3 in U_FT z2 /\ C;
  then reconsider y4=y3 as Element of FT;
  y3 in U_FT z2 by A13,XBOOLE_0:def 4;
  then z2 in U_FT y4 by A1;
  then z2 in U_FT y4 /\ Q2 by A7,A11,XBOOLE_0:def 4;
  then
A14: U_FT y4 meets Q2;
  set P3=P2/\C,Q3=Q2/\C;
A15: C = A /\ C by A3,XBOOLE_1:28
    .=P3 \/ Q3 by A5,XBOOLE_1:23;
  set x = the Element of P2;
A16: x in P2 by A6;
  P2 c= P2\/Q2 by XBOOLE_1:7;
  then P2 c= C^b by A4,A5;
  then x in C^b by A16;
  then consider z being Element of FT such that
A17: z=x and
A18: U_FT z meets C;
  set y = the Element of U_FT z /\ C;
A19: U_FT z /\ C <> {} by A18;
  then y in U_FT z /\ C;
  then reconsider y2=y as Element of FT;
  y in U_FT z by A19,XBOOLE_0:def 4;
  then z in U_FT y2 by A1;
  then z in (U_FT y2)/\P2 by A6,A17,XBOOLE_0:def 4;
  then (U_FT y2) meets P2;
  then
A20: y2 in P2^b;
A21: y4 in C by A13,XBOOLE_0:def 4;
A22: now
    assume Q3={};
    then
A23: y4 in P2 by A21,A15,XBOOLE_0:def 4;
    consider w being Element of FT such that
A24: w=y4 and
A25: U_FT w meets Q2 by A14;
    consider s being object such that
A26: s in U_FT w and
A27: s in Q2 by A25,XBOOLE_0:3;
    reconsider s2=s as Element of FT by A26;
    w in U_FT s2 by A1,A26;
    then U_FT s2 meets P2 by A23,A24,XBOOLE_0:3;
    then s2 in P2^b;
    hence contradiction by A9,A27,XBOOLE_0:3;
  end;
A28: P3 c= P2 by XBOOLE_1:17;
A29: y2 in C by A19,XBOOLE_0:def 4;
A30: now
    assume P3={};
    then y2 in Q2 by A29,A15,XBOOLE_0:def 4;
    then y2 in P2^b /\ Q2 by A20,XBOOLE_0:def 4;
    hence contradiction by A9;
  end;
  P3 misses Q2 by A8,XBOOLE_1:17,63;
  then P3 misses Q3 by XBOOLE_1:17,63;
  then P3^b meets Q3 by A2,A15,A30,A22;
  then P2^b meets Q3 by A28,FIN_TOPO:14,XBOOLE_1:63;
  hence contradiction by A9,XBOOLE_1:17,63;
end;
