
theorem Th35:
  for T being non empty TopStruct, x being Point of T, Y being
Subset of T, S being sequence of T st Y = { y where y is Point of T : x in Cl({
  y}) } & rng S misses Y & S is_convergent_to x ex S1 being subsequence of S st
  S1 is one-to-one
proof
  let T be non empty TopStruct, x be Point of T, Y be Subset of T, S be
  sequence of T;
  assume that
A1: Y = { y where y is Point of T : x in Cl({y}) } and
A2: rng S /\ Y = {} and
A3: S is_convergent_to x;
  defpred P[Nat,set,set] means $3 in NAT & for n1,n2,m being
  Element of NAT st n1=$2 & n2=$3 & n2 <= m holds S.m <> S.n1;
A4: for z being set st z in rng S ex n0 being Element of NAT st for m being
  Element of NAT st n0 <= m holds z <> S.m
  proof
    let z be set;
    defpred P[set] means $1 = z;
    assume
A5: z in rng S;
    then reconsider z9=z as Point of T;
    assume
    for n0 being Element of NAT ex m being Element of NAT st n0 <= m & z = S.m;
    then
A6: for n being Element of NAT ex m being Element of NAT st n <= m & P[S.m ];
    ex S1 being subsequence of S st for n being Element of NAT holds P[S1.n
    ] from VALUED_1:sch 1(A6 );
    then x in Cl({z9}) by A3,Th15,Th34;
    then z9 in Y by A1;
    hence contradiction by A2,A5,XBOOLE_0:def 4;
  end;
A7: for n being Nat for z1 being set ex z2 being set st P[n,z1, z2]
  proof
    let n be Nat, z1 be set;
    per cases;
    suppose
A8:   not z1 in NAT;
      take 0;
      thus 0 in NAT;
      let n1,n2,m be Element of NAT;
      assume that
A9:   n1=z1 and
      n2=0 and
      n2 <= m;
      thus thesis by A8,A9;
    end;
    suppose
      z1 in NAT;
      then z1 in dom S by NORMSP_1:12;
      then S.z1 in rng S by FUNCT_1:def 3;
      then consider n0 being Element of NAT such that
A10:  for m being Element of NAT st n0 <= m holds S.z1 <> S.m by A4;
      take n0;
      thus n0 in NAT;
      let n1,n2,m be Element of NAT;
      assume n1=z1 & n2=n0 & n2 <= m;
      hence thesis by A10;
    end;
  end;
  consider f being Function such that
A11: dom f = NAT and
A12: f.0 = 0 and
A13: for n being Nat holds P[n,f.n,f.(n+1)] from RECDEF_1:sch
  1(A7);
A14: for n being Nat  holds f.n is Element of NAT
  proof
    let n be Nat;
A15:  n in NAT by ORDINAL1:def 12;
    per cases;
    suppose
      n = 0;
      hence thesis by A12;
    end;
    suppose
      n <> 0;
      then 0 < n by NAT_1:3;
      then 0 + 1 < n + 1 by XREAL_1:6;
      then 1 <= n by NAT_1:13;
      then reconsider n1=n-1 as Element of NAT by INT_1:5,A15;
      n1 + 1 = n;
      hence thesis by A13;
    end;
  end;
  then for n be Nat holds f.n is real;
  then reconsider f as Real_Sequence by A11,SEQ_1:2;
  f is increasing
  proof
    let n be Nat;
     reconsider nn=n, nn1=n+1 as Element of NAT by ORDINAL1:def 12;
    reconsider n2=f.(nn1) as Element of NAT by A14;
    reconsider n1=f.nn as Element of NAT by A14;
    assume f.n >= f.(n+1);
    then n2 <= n1;
    then S.n1 <> S.n1 by A13;
    hence contradiction;
  end;
  then reconsider f as increasing sequence of NAT by A14,SEQM_3:13;
  take S1=S*f;
A16: for n1,n2 being Element of NAT st n1 < n2 holds S1.n1 <> S1.n2
  proof
    let n1,n2 be Element of NAT;
    reconsider n19=f.n1 as Element of NAT;
    n2 in NAT;
    then n2 in dom S1 by NORMSP_1:12;
    then
A17: S.(f.n2) = S1.n2 by FUNCT_1:12;
    assume n1 < n2;
    then
A18: n1 + 1 <= n2 by NAT_1:13;
    f.(n1+1) <= f.n2
    proof
      per cases;
      suppose
        n1+1 = n2;
        hence thesis;
      end;
      suppose
        n1 + 1 <> n2;
        then n1 + 1 < n2 by A18,XXREAL_0:1;
        hence thesis by SEQM_3:1;
      end;
    end;
    then
A19: S.(f.n2) <> S.n19 by A13;
    n1 in NAT;
    then n1 in dom S1 by NORMSP_1:12;
    hence thesis by A19,A17,FUNCT_1:12;
  end;
  let x1,x2 be object;
  assume that
A20: x1 in dom S1 and
A21: x2 in dom S1 and
A22: S1.x1 = S1.x2;
  reconsider n2=x2 as Element of NAT by A21;
  reconsider n1=x1 as Element of NAT by A20;
  assume
A23: x1 <> x2;
  per cases by A23,XXREAL_0:1;
  suppose
    n1 < n2;
    hence contradiction by A22,A16;
  end;
  suppose
    n2 < n1;
    hence contradiction by A22,A16;
  end;
end;
