reserve D for non empty set;
reserve f1,f2 for FinSequence of D;
reserve i,n,n1,n2,n3,n4,n5,n6 for Element of NAT;
reserve S for Gene-Set;
reserve p1,p2 for Individual of S;

theorem Th35:
  (n1 >= len p1 & n2 >= len p1 & n3 >= len p1 implies crossover(p1
,p2,n1,n2,n3,n4) = crossover(p1,p2,n4)) & (n1 >= len p1 & n2 >= len p1 & n4 >=
len p1 implies crossover(p1,p2,n1,n2,n3,n4) = crossover(p1,p2,n3)) & (n1 >= len
  p1 & n3 >= len p1 & n4 >= len p1 implies crossover(p1,p2,n1,n2,n3,n4) =
  crossover(p1,p2,n2)) & (n2 >= len p1 & n3 >= len p1 & n4 >= len p1 implies
  crossover(p1,p2,n1,n2,n3,n4) = crossover(p1,p2,n1))
proof
A1: n1 >= len p1 & n2 >= len p1 & n3 >= len p1 implies crossover(p1,p2,n1,n2
  ,n3,n4) = crossover(p1,p2,n4)
  proof
    assume that
A2: n1 >= len p1 & n2 >= len p1 and
A3: n3 >= len p1;
    crossover(p1,p2,n1,n2,n3,n4) = crossover(p1,p2,n3,n4) by A2,Th34;
    hence thesis by A3,Th9;
  end;
A4: n1 >= len p1 & n3 >= len p1 & n4 >= len p1 implies crossover(p1,p2,n1,
  n2,n3,n4) = crossover(p1,p2,n2)
  proof
    assume that
A5: n1 >= len p1 & n3 >= len p1 and
A6: n4 >= len p1;
    crossover(p1,p2,n1,n2,n3,n4) = crossover(p1,p2,n2,n4) by A5,Th34
      .= crossover(p1,p2,n4,n2) by Th13;
    hence thesis by A6,Th9;
  end;
A7: n2 >= len p1 & n3 >= len p1 & n4 >= len p1 implies crossover(p1,p2,n1,
  n2,n3,n4) = crossover(p1,p2,n1)
  proof
    assume that
A8: n2 >= len p1 & n3 >= len p1 and
A9: n4 >= len p1;
    crossover(p1,p2,n1,n2,n3,n4) = crossover(p1,p2,n1,n4) by A8,Th34
      .= crossover(p1,p2,n4,n1) by Th13;
    hence thesis by A9,Th9;
  end;
  n1 >= len p1 & n2 >= len p1 & n4 >= len p1 implies crossover(p1,p2,n1,n2
  ,n3,n4) = crossover(p1,p2,n3)
  proof
    assume that
A10: n1 >= len p1 & n2 >= len p1 and
A11: n4 >= len p1;
    crossover(p1,p2,n1,n2,n3,n4) = crossover(p1,p2,n3,n4) by A10,Th34
      .= crossover(p1,p2,n4,n3) by Th13;
    hence thesis by A11,Th9;
  end;
  hence thesis by A1,A4,A7;
end;
