reserve n for Nat,
  i,j for Nat,
  r,s,r1,s1,r2,s2,r9,s9 for Real,
  p,q for Point of TOP-REAL 2,
  G for Go-board,
  x,y for set,
  v for Point of Euclid 2;

theorem Th35:
  1 <= j & j+1 <= width G implies 1/2*(G*(1,j)+G*(1,j+1))-|[1,0]|
  in Int cell(G,0,j)
proof
  assume that
A1: 1 <= j and
A2: j+1 <= width G;
  set s1 = G*(1,j)`2, r1 = G*(1,j)`1, s2 = G*(1,j+1)`2;
  len G <> 0 by MATRIX_0:def 10;
  then
A3: 1 <= len G by NAT_1:14;
  len G <> 0 by MATRIX_0:def 10;
  then
A4: 1 <= len G by NAT_1:14;
  j < j+1 by XREAL_1:29;
  then
A5: s1 < s2 by A1,A2,A4,GOBOARD5:4;
  then s1+s1 < s1+s2 by XREAL_1:6;
  then
A6: 1/2*(s1+s1) < 1/2*(s1+s2) by XREAL_1:68;
  j < width G by A2,NAT_1:13;
  then
A7: G*(1,1)`1 = r1 by A1,A3,GOBOARD5:2;
  then r1 < G*(1,1)`1+1 by XREAL_1:29;
  then
A8: r1-1 < G*(1,1)`1 by XREAL_1:19;
  1 <= j+1 by NAT_1:11;
  then G*(1,1)`1 = G*(1,j+1)`1 by A2,A3,GOBOARD5:2;
  then G*(1,j) = |[r1,s1]| & G*(1,j+1) = |[r1,s2]| by A7,EUCLID:53;
  then 1/2*(r1+r1) = r1 & G*(1,j)+G*(1,j+1) = |[r1+r1,s1+s2]| by EUCLID:56;
  then 1/2*(G*(1,j)+G*(1,j+1))= |[r1,1/2*(s1+s2)]| by EUCLID:58;
  then
A9: 1/2*(G*(1,j)+G*(1,j+1))-|[1,0]| = |[r1-1,1/2*(s1+s2)-0]| by EUCLID:62
    .= |[r1-1,1/2*(s1+s2)]|;
  s1+s2 < s2+s2 by A5,XREAL_1:6;
  then
A10: 1/2*(s1+s2) < 1/2*(s2+s2) by XREAL_1:68;
  j < width G by A2,NAT_1:13;
  then
  Int cell(G,0,j) = { |[r,s]| : r < G*(1,1)`1 & G*(1,j)`2 < s & s < G*(1,
  j+1)`2 } by A1,Th20;
  hence thesis by A9,A6,A10,A8;
end;
