reserve i,j,k,i1,j1 for Nat,
  p for Point of TOP-REAL 2,
  x for set;
reserve f for non constant standard special_circular_sequence;
reserve P for Subset of TOP-REAL 2;

theorem
  LSeg((GoB f)*(len GoB f,1)+|[1,-1]|, 1/2*((GoB f)*(len GoB f,1)+(GoB f
  )*(len GoB f,2))+|[1,0]|) misses L~f
proof
A1: 1 <= len GoB f by GOBOARD7:32;
  now
    1 < width GoB f by GOBOARD7:33;
    then 1+1 <= width GoB f by NAT_1:13;
    then
A2: (GoB f)*(len GoB f,2)`1 = (GoB f)*(len GoB f,1)`1 by A1,GOBOARD5:2;
    (1/2*((GoB f)*(len GoB f,1)+(GoB f)*(len GoB f,2))+|[1,0]|)`1 = (1/2*(
    (GoB f)*(len GoB f,1)+(GoB f)*(len GoB f,2)))`1+|[1,0]|`1 by TOPREAL3:2
      .= 1/2*((GoB f)*(len GoB f,1)+(GoB f)*(len GoB f,2))`1+|[1,0]|`1 by
TOPREAL3:4
      .= 1/2*((GoB f)*(len GoB f,1)`1+(GoB f)*(len GoB f,1)`1)+|[1,0]|`1 by A2,
TOPREAL3:2
      .= 1*((GoB f)*(len GoB f,1))`1+1 by EUCLID:52;
    then
A3: 1/2*((GoB f)*(len GoB f,1)+(GoB f)*(len GoB f,2))+|[1,0]| = |[(GoB f)
*(len GoB f,1)`1+1, (1/2*((GoB f)*(len GoB f,1)+(GoB f)*(len GoB f,2))+|[1,0]|)
    `2]| by EUCLID:53;
    ((GoB f)*(len GoB f,1)+|[1,-1]|)`1 = ((GoB f)*(len GoB f,1))`1+|[1,-1
    ]|`1 by TOPREAL3:2
      .= (GoB f)*(len GoB f,1)`1+1 by EUCLID:52;
    then
A4: (GoB f)*(len GoB f,1)+|[1,-1]| = |[(GoB f)*(len GoB f,1)`1+1,((GoB f)*
    (len GoB f,1)+|[1,-1]|)`2]| by EUCLID:53;
    let p;
    assume p in LSeg((GoB f)*(len GoB f,1)+|[1,-1]|, 1/2*((GoB f)*(len GoB f,
    1)+(GoB f)*(len GoB f,2))+|[1,0]|);
    then p`1 = (GoB f)*(len GoB f,1)`1 + 1 by A4,A3,TOPREAL3:11;
    hence p`1 > (GoB f)*(len GoB f,1)`1 by XREAL_1:29;
  end;
  hence thesis by Th22;
end;
