reserve x,y,X,Y for set,
  k,l,n for Nat,
  i,i1,i2,i3,j for Integer,
  G for Group,
  a,b,c,d for Element of G,
  A,B,C for Subset of G,
  H,H1,H2, H3 for Subgroup of G,
  h for Element of H,
  F,F1,F2 for FinSequence of the carrier of G,
  I,I1,I2 for FinSequence of INT;

theorem Th35:
  gr A = gr(A \ {1_G})
proof
  set X = {B : ex H being strict Subgroup of G st B = the carrier of H & A c=
  carr H};
  set Y = {C : ex H being strict Subgroup of G st C = the carrier of H & A \ {
  1_G} c= carr H};
A1: X = Y
  proof
    thus X c= Y
    proof
      let x be object;
      assume x in X;
      then consider B such that
A2:   x = B and
A3:   ex H being strict Subgroup of G st B = the carrier of H & A c= carr H;
      consider H being strict Subgroup of G such that
A4:   B = the carrier of H and
A5:   A c= carr H by A3;
      A \ {1_G} c= A by XBOOLE_1:36;
      then A \ {1_G} c= carr H by A5;
      hence thesis by A2,A4;
    end;
    let x be object;
    assume x in Y;
    then consider B such that
A6: x = B and
A7: ex H being strict Subgroup of G st B = the carrier of H & A \ {
    1_G} c= carr H;
    consider H being strict Subgroup of G such that
A8: B = the carrier of H and
A9: A \ {1_G} c= carr H by A7;
    1_G in H by GROUP_2:46;
    then 1_G in carr H by STRUCT_0:def 5;
    then {1_G} c= carr H by ZFMISC_1:31;
    then
A10: (A \ {1_G}) \/ {1_G} c= carr H by A9,XBOOLE_1:8;
    now
      per cases;
      suppose
        1_G in A;
        then {1_G} c= A by ZFMISC_1:31;
        hence A c= carr H by A10,XBOOLE_1:45;
      end;
      suppose
        not 1_G in A;
        hence A c= carr H by A9,ZFMISC_1:57;
      end;
    end;
    hence thesis by A6,A8;
  end;
  the carrier of gr A = meet X by Th34
    .= the carrier of gr(A \ {1_G}) by A1,Th34;
  hence thesis by GROUP_2:59;
end;
