reserve r,x,x0,a,b for Real;
reserve n,m for Element of NAT;
reserve A for non empty closed_interval Subset of REAL;
reserve Z for open Subset of REAL;
reserve f, f1, f2, f3 for PartFunc of REAL, REAL;

theorem
  not 0 in Z & A c= Z & (for x st x in Z holds x<>0 & f.x = -1/x^2) &
dom f = Z & f|A is continuous implies integral(f,A) =
 ((id Z)^).(upper_bound A)-((id Z)
  ^).(lower_bound A)
proof
  set g = id Z;
  assume that
A1: not 0 in Z and
A2: A c= Z and
A3: for x st x in Z holds x<>0 & f.x = -1/x^2 and
A4: dom f = Z and
A5: f|A is continuous;
A6: f is_integrable_on A by A2,A4,A5,INTEGRA5:11;
A7: g^ is_differentiable_on Z by A1,FDIFF_5:4;
A8: for x being Element of REAL st x in dom ((g^)`|Z) holds ((g^)`|Z).x = f.x
  proof
    let x be Element of REAL;
    assume x in dom ((g^)`|Z);
    then
A9: x in Z by A7,FDIFF_1:def 7;
    then ((g^)`|Z).x = -1/x^2 by A1,FDIFF_5:4
      .= f.x by A3,A9;
    hence thesis;
  end;
  dom ((g^)`|Z) = dom f by A4,A7,FDIFF_1:def 7;
  then ((g^)`|Z) = f by A8,PARTFUN1:5;
  hence thesis by A2,A4,A5,A6,A7,INTEGRA5:10,13;
end;
