 reserve h,h1 for 0-convergent non-zero Real_Sequence,
         c,c1 for constant Real_Sequence;

theorem Th35:
  for a,b be Real, f,F be PartFunc of REAL,REAL st
   a < b & [.a,b.] c= dom f & f|[.a,b.] is continuous & [.a,b.] c= dom F &
   (for x be Real st x in [.a,b.] holds F.x = integral(f,a,x)) holds
    F is_right_differentiable_in a & Rdiff(F,a) = lim_right(F`|(].a,b.[),a)
proof
    let a,b be Real, f,F be PartFunc of REAL,REAL;
    assume that
A1:  a < b and
A2:  [.a,b.] c= dom f and
A3:  f|[.a,b.] is continuous and
A4:  [.a,b.] c= dom F and
A5:  for x be Real st x in [.a,b.] holds F.x = integral(f,a,x);
A6: [.a,b.] = ['a,b'] by A1,INTEGRA5:def 3;
    ].a,b.[ c= [.a,b.] by XXREAL_1:25; then
A7: ].a,b.[ c= dom f & ].a,b.[ c= dom F by A2,A4;
A8: [.a,b.[ c= [.a,b.] by XXREAL_1:24; then
A9: [.a,b.[ c= dom F by A4;

    for x be Real st x in ].a,b.[ holds F|(].a,b.[) is_differentiable_in x
    proof
     let x be Real;
     assume A10: x in ].a,b.[; then
     F is_differentiable_in x by A1,A2,A3,A4,A5,Th32;
     hence F|(].a,b.[) is_differentiable_in x by A10,PDIFFEQ1:2;
    end; then
A11:F is_differentiable_on ].a,b.[ by A7;

A12:F`|(].a,b.[) is_right_convergent_in a by A1,A2,A3,A4,A5,Th34;

A13:dom(F|[.a,b.]) = [.a,b.] by A4,RELAT_1:62;
A14:for x be Real st x in [.a,b.] holds (F|[.a,b.]).x = integral(f,a,x)
    proof
     let x be Real;
     assume A15: x in [.a,b.]; then
     (F|[.a,b.]).x = F.x by FUNCT_1:49;
     hence thesis by A15,A5;
    end;

    f|['a,b'] is bounded & f is_integrable_on ['a,b']
      by A2,A3,A6,INTEGRA5:10,11; then
    F|[.a,b.[ is Lipschitzian by A8,A1,A2,A13,A14,Th33,FCONT_1:33;
    hence F is_right_differentiable_in a &
     Rdiff(F,a) = lim_right(F`|(].a,b.[),a) by A1,A9,A11,A12,Th4;
end;
