reserve k,t,i,j,m,n for Nat,
  x,y,y1,y2 for object,
  D for non empty set;
reserve K for Field,
  V for VectSp of K,
  a for Element of K,
  W for Element of V;
reserve KL1,KL2,KL3 for Linear_Combination of V,
  X for Subset of V;
reserve s for FinSequence,
  V1,V2,V3 for finite-dimensional VectSp of K,
  f,f1,f2 for Function of V1,V2,
  g for Function of V2,V3,
  b1 for OrdBasis of V1,
  b2 for OrdBasis of V2,
  b3 for OrdBasis of V3,
  v1,v2 for Vector of V2,
  v,w for Element of V1;
reserve p2,F for FinSequence of V1,
  p1,d for FinSequence of K,
  KL for Linear_Combination of V1;

theorem Th35:
  v = Sum lmlt(v|--b1,b1)
proof
  consider KL be Linear_Combination of V1 such that
A1: v = Sum KL & Carrier KL c= rng b1 and
A2: for k st 1<=k & k<=len (v|--b1) holds (v|--b1)/.k=KL.(b1/.k) by Def7;
  len (v|--b1) = len b1 by Def7;
  then
A3: dom (v|--b1) = dom b1 by FINSEQ_3:29;
  then
A4: dom b1 = dom lmlt(v|--b1,b1) by Th12;
 len (KL (#) b1) = len b1 by VECTSP_6:def 5
    .= len lmlt(v|--b1,b1) by A4,FINSEQ_3:29; then
A5: dom (KL (#) b1) = dom lmlt(v|--b1,b1) by FINSEQ_3:29;
A6: now
    let t be Nat;
    assume
A7: t in dom lmlt(v|--b1,b1);
    then
A8: b1/.t = b1.t by A4,PARTFUN1:def 6;
    t in dom (v|--b1) by A3,A7,Th12;
    then
A9: t<=len (v|--b1) by FINSEQ_3:25;
A10: 1<=t by A7,FINSEQ_3:25;
    then
A11: (v|--b1)/.t = (v|--b1).t by A9,FINSEQ_4:15;
    t in dom (KL (#) b1) by A5,A7;
    hence (KL (#) b1).t = KL.(b1/.t) * (b1/.t) by VECTSP_6:def 5
      .= ((v|--b1)/.t) * (b1/.t) by A2,A10,A9
      .= (the lmult of V1).((v|--b1).t,b1.t) by A8,A11,VECTSP_1:def 12
      .= lmlt(v|--b1,b1).t by A7,FUNCOP_1:22;
  end;
  b1 is one-to-one by Def2;
  hence v = Sum(KL (#) b1) by A1,Th20
    .= Sum lmlt(v|--b1,b1) by A5,A6,FINSEQ_1:13;
end;
