reserve A,B,a,b,c,d,e,f,g,h for set;

theorem Th35:
  for G being RelStr, H1,H2 being non empty RelStr, x being
Element of H1, y being Element of H2 st G = union_of(H1,H2) & the carrier of H1
  misses the carrier of H2 holds not [x,y] in the InternalRel of G
proof
  let G be RelStr;
  let H1,H2 be non empty RelStr;
  let x be Element of H1;
  let y be Element of H2;
  assume that
A1: G = union_of(H1,H2) and
A2: (the carrier of H1) misses (the carrier of H2);
  assume not thesis;
  then
A3: [x,y] in (the InternalRel of H1) \/ the InternalRel of H2 by A1,
NECKLA_2:def 2;
  per cases by A3,XBOOLE_0:def 3;
  suppose
    [x,y] in (the InternalRel of H1);
    then y in the carrier of H1 by ZFMISC_1:87;
    then y in (the carrier of H1) /\ the carrier of H2 by XBOOLE_0:def 4;
    hence thesis by A2;
  end;
  suppose
    [x,y] in (the InternalRel of H2);
    then x in the carrier of H2 by ZFMISC_1:87;
    then x in (the carrier of H1) /\ the carrier of H2 by XBOOLE_0:def 4;
    hence thesis by A2;
  end;
end;
