reserve D for set;
reserve x,x0,x1,x2,y,y0,y1,y2,z,z0,z1,z2,r,s,t for Real;
reserve p,a,u,u0 for Element of REAL 3;
reserve n,m,k for Element of NAT;
reserve f,f1,f2,f3,g for PartFunc of REAL 3,REAL;
reserve R,R1,R2 for RestFunc;
reserve L,L1,L2 for LinearFunc;

theorem Th35:
  (f is_partial_differentiable_in p,1 & f is_partial_differentiable_in p,2 &
  f is_partial_differentiable_in p,3 & g is_partial_differentiable_in p,1 &
  g is_partial_differentiable_in p,2 & g is_partial_differentiable_in p,3)
  implies grad(f+g,p) = grad(f,p)+grad(g,p)
proof
    assume that
A1: f is_partial_differentiable_in p,1 & f is_partial_differentiable_in p,2 &
    f is_partial_differentiable_in p,3 and
A2: g is_partial_differentiable_in p,1 & g is_partial_differentiable_in p,2 &
    g is_partial_differentiable_in p,3;
    grad(f+g,p)
    = |[ partdiff(f+g,p,1),partdiff(f+g,p,2),partdiff(f+g,p,3) ]| by Th34
   .= |[ partdiff(f,p,1)+partdiff(g,p,1),partdiff(f+g,p,2),partdiff(f+g,p,3) ]|
      by A1,A2,PDIFF_1:29
   .= |[ partdiff(f,p,1)+partdiff(g,p,1),partdiff(f,p,2)+partdiff(g,p,2),
      partdiff(f+g,p,3) ]| by A1,A2,PDIFF_1:29
   .= |[ partdiff(f,p,1)+partdiff(g,p,1),partdiff(f,p,2)+partdiff(g,p,2),
      partdiff(f,p,3)+partdiff(g,p,3) ]| by A1,A2,PDIFF_1:29
   .= |[ partdiff(f,p,1),partdiff(f,p,2),partdiff(f,p,3) ]|+
      |[ partdiff(g,p,1),partdiff(g,p,2),partdiff(g,p,3) ]| by Lm4
   .= grad(f,p)+|[ partdiff(g,p,1),partdiff(g,p,2),partdiff(g,p,3) ]| by Th34
   .= grad(f,p)+grad(g,p) by Th34;
    hence thesis;
end;
