reserve T for TopStruct;
reserve GX for TopSpace;
reserve T for TopStruct,
  x,y for Point of T;

theorem Th35:
  for S,T being TopStruct holds S is SubSpace of T iff S is
  SubSpace of the TopStruct of T
proof
  let S,T be TopStruct;
  thus S is SubSpace of T implies S is SubSpace of the TopStruct of T
  proof
    assume
A1: S is SubSpace of T;
    then [#]S c= [#]T by Def4;
    hence [#]S c= [#]the TopStruct of T;
    let P be Subset of S;
    thus P in the topology of S implies ex Q being Subset of the TopStruct of
    T st Q in the topology of the TopStruct of T & P = Q /\ [#]S by A1,Def4;
    given Q being Subset of the TopStruct of T such that
A2: Q in the topology of the TopStruct of T & P = Q /\ [#]S;
    thus P in the topology of S by A1,A2,Def4;
  end;
  assume
A3: S is SubSpace of the TopStruct of T;
  then [#]S c= [#]the TopStruct of T by Def4;
  hence [#]S c= [#]T;
  let P be Subset of S;
  thus P in the topology of S implies ex Q being Subset of T st Q in the
  topology of T & P = Q /\ [#]S by A3,Def4;
  given Q being Subset of T such that
A4: Q in the topology of T & P = Q /\ [#]S;
  thus P in the topology of S by A3,A4,Def4;
end;
