reserve x,x0, r,r1,r2 for Real,
      th for Real,

  rr for set,

  rseq for Real_Sequence;

theorem Th35:
  for x be set st x in [.-PI/2,-PI/4.] holds cosec.x in [.-sqrt 2, -1.]
proof
  let x be set;
  PI/4 < PI/2 by XREAL_1:76;
  then
A1: -PI/2 < -PI/4 by XREAL_1:24;
  assume x in [.-PI/2,-PI/4.];
  then x in ].-PI/2,-PI/4.[ \/ {-PI/2,-PI/4} by A1,XXREAL_1:128;
  then
A2: x in ].-PI/2,-PI/4.[ or x in {-PI/2,-PI/4} by XBOOLE_0:def 3;
  per cases by A2,TARSKI:def 2;
  suppose
A3: x in ].-PI/2,-PI/4.[;
    then
A4: ex s be Real st s=x & -PI/2 < s & s < -PI/4;
A5: ex s be Real st s=x & -PI/2 < s & s < -PI/4 by A3;
A6: ].-PI/2,-PI/4.[ c= [.-PI/2,-PI/4.] by XXREAL_1:25;
    -PI/2 in [.-PI/2,0.[ & -PI/4 in [.-PI/2,0.[ by A1;
    then
A7: [.-PI/2,-PI/4.] c= [.-PI/2,0.[ by XXREAL_2:def 12;
    then
A8: cosec|[.-PI/2,-PI/4.] is decreasing by Th19,RFUNCT_2:29;
A9: [.-PI/2,-PI/4.] /\ dom cosec = [.-PI/2,-PI/4.] by A7,Th3,XBOOLE_1:1,28;
    then -PI/4 in [.-PI/2,-PI/4.] /\ dom cosec by A1;
    then
A10: cosec.x > -sqrt 2 by A3,A8,A9,A6,A5,Th32,RFUNCT_2:21;
    -PI/2 in [.-PI/2,-PI/4.] by A1;
    then -1 > cosec.x by A3,A8,A9,A6,A4,Th32,RFUNCT_2:21;
    hence thesis by A10;
  end;
  suppose
A11: x = -PI/2;
    -sqrt 2 < -1 by SQUARE_1:19,XREAL_1:24;
    hence thesis by A11,Th32;
  end;
  suppose
A12: x = -PI/4;
    -sqrt 2 < -1 by SQUARE_1:19,XREAL_1:24;
    hence thesis by A12,Th32;
  end;
end;
