reserve N for Nat;
reserve n,m,n1,n2 for Nat;
reserve q,r,r1,r2 for Real;
reserve x,y for set;
reserve w,w1,w2,g,g1,g2 for Point of TOP-REAL N;
reserve seq,seq1,seq2,seq3,seq9 for Real_Sequence of N;

theorem Th35:
  for n ex r st (0<r & for m st m<=n holds |.seq.m.| < r)
proof
  defpred X[Nat] means
   ex r1 st 0<r1 & for m st m<=$1 holds |.seq.m.|<r1;
A1: for n st X[n] holds X[n+1]
  proof
    let n;
    given r1 such that
A2: 0<r1 and
A3: for m st m<=n holds |.seq.m.|<r1;
A4: now
      assume
A5:   r1<=|.seq.(n+1).|;
      take r=|.seq.(n+1).|+1;
      thus 0<r;
      let m such that
A6:   m<=n+1;
A7:   now
        assume m<=n;
        then |.seq.m.|<r1 by A3;
        then |.seq.m.|<|.seq.(n+1).| by A5,XXREAL_0:2;
        then |.seq.m.|+0<r by XREAL_1:8;
        hence |.seq.m.|<r;
      end;
      now
        assume m=n+1;
        then |.seq.m.|+0<r by XREAL_1:8;
        hence |.seq.m.|<r;
      end;
      hence |.seq.m.|<r by A6,A7,NAT_1:8;
    end;
    now
      assume
A8:   |.seq.(n+1).|<=r1;
      take r=r1+1;
      thus 0<r by A2;
      let m such that
A9:   m<=n+1;
A10:  now
        assume m<=n;
        then
A11:    |.seq.m.|<r1 by A3;
        r1+0<r by XREAL_1:8;
        hence |.seq.m.|<r by A11,XXREAL_0:2;
      end;
      now
A12:    r1+0<r by XREAL_1:8;
        assume m=n+1;
        hence |.seq.m.|<r by A8,A12,XXREAL_0:2;
      end;
      hence |.seq.m.|<r by A9,A10,NAT_1:8;
    end;
    hence thesis by A4;
  end;
A13: X[0]
  proof
    take r=|.seq.0 .|+1;
    thus 0<r;
    let m;
    assume m<=0;
    then 0=m;
    then |.seq.m.|+0<r by XREAL_1:8;
    hence thesis;
  end;
  thus for n holds X[n] from NAT_1:sch 2(A13,A1);
end;
