
theorem Th35:
  for X being monotone-convergence non empty TopSpace, Y being
  T_0-TopSpace, f being continuous Function of Omega X, Omega Y holds f is
  directed-sups-preserving
proof
  let X be monotone-convergence non empty TopSpace, Y be T_0-TopSpace, f be
  continuous Function of Omega X, Omega Y;
  let D be non empty directed Subset of Omega X;
  assume
A1: ex_sup_of D,Omega X;
  set V = (downarrow sup (f.:D))`;
A2: the TopStruct of X = the TopStruct of Omega X by Def2;
  then reconsider fV = f"V as Subset of X;
  [#]Omega Y <> {};
  then f"V is open by TOPS_2:43;
  then reconsider fV as open Subset of X by A2,TOPS_3:76;
  sup (f.:D) <= sup (f.:D);
  then
A3: sup (f.:D) in downarrow sup (f.:D) by WAYBEL_0:17;
A4: the TopStruct of Y = the TopStruct of Omega Y by Def2;
  ex a being Element of Omega Y st f.:D is_<=_than a & for b being Element
  of Omega Y st f.:D is_<=_than b holds a <= b
  proof
    take a = f.sup D;
    D is_<=_than sup D by A1,YELLOW_0:def 9;
    hence f.:D is_<=_than a by YELLOW_2:14;
    let b be Element of Omega Y such that
A5: for c being Element of Omega Y st c in f.:D holds c <= b;
    reconsider Z = {b} as Subset of Y by Lm1;
    for G being Subset of Y st G is open holds a in G implies Z meets G
    proof
      let G be Subset of Y such that
A6:   G is open and
A7:   a in G;
      reconsider H = G as open Subset of Omega Y by A4,A6,TOPS_3:76;
      [#]Omega Y <> {};
      then f"H is open by TOPS_2:43;
      then
A8:   f"H is open Subset of X by A2,TOPS_3:76;
      sup D in f"H by A7,FUNCT_2:38;
      then D meets f"H by A8,Def4;
      then consider c being object such that
A9:   c in D and
A10:  c in f"H by XBOOLE_0:3;
      reconsider c as Point of Omega X by A9;
A11:  f.c in H by A10,FUNCT_2:38;
      f.c <= b by A5,A9,FUNCT_2:35;
      then
A12:  b in G by A11,WAYBEL_0:def 20;
      b in {b} by TARSKI:def 1;
      hence thesis by A12,XBOOLE_0:3;
    end;
    then a in Cl Z by A4,PRE_TOPC:def 7;
    hence thesis by Def2;
  end;
  hence
A13: ex_sup_of f.:D,Omega Y by YELLOW_0:15;
  assume
A14: sup (f.:D) <> f.sup D;
  sup (f.:D) <= f.sup D by A1,A13,WAYBEL17:15;
  then not f.sup D <= sup (f.:D) by A14,ORDERS_2:2;
  then not f.sup D in downarrow sup (f.:D) by WAYBEL_0:17;
  then f.sup D in V by XBOOLE_0:def 5;
  then sup D in fV by FUNCT_2:38;
  then D meets fV by Def4;
  then consider d being object such that
A15: d in D and
A16: d in fV by XBOOLE_0:3;
  reconsider d as Element of Omega X by A15;
A17: f.d in V by A16,FUNCT_2:38;
  f.d <= sup (f.:D) by A13,A15,FUNCT_2:35,YELLOW_4:1;
  then sup (f.:D) in V by A17,WAYBEL_0:def 20;
  hence contradiction by A3,XBOOLE_0:def 5;
end;
