reserve
  S for (4,1) integer bool-correct non empty non void BoolSignature,
  X for non-empty ManySortedSet of the carrier of S,
  T for vf-free integer all_vars_including inheriting_operations free_in_itself
  (X,S)-terms VarMSAlgebra over S,
  C for (4,1) integer bool-correct non-empty image of T,
  G for basic GeneratorSystem over S,X,T,
  A for IfWhileAlgebra of the generators of G,
  I for integer SortSymbol of S,
  x,y,z,m for pure (Element of (the generators of G).I),
  b for pure (Element of (the generators of G).the bool-sort of S),
  t,t1,t2 for Element of T,I,
  P for Algorithm of A,
  s,s1,s2 for Element of C-States(the generators of G);
reserve
  f for ExecutionFunction of A, C-States(the generators of G),
  (\falseC)-States(the generators of G, b);
reserve u for ManySortedFunction of FreeGen T, the Sorts of C;

theorem Th36:
  \0(T,I) value_at(C,s) = 0
  proof
A1: s is ManySortedFunction of the generators of G, the Sorts of C
    by AOFA_A00:48;
    then consider f being ManySortedFunction of T,C such that
A2: f is_homomorphism T,C & s = f||(the generators of G) by AOFA_A00:def 19;
    the generators of G is_transformable_to the Sorts of C
    by MSAFREE4:21;
    then
    doms s = the generators of G by A1,MSSUBFAM:17;
    then consider f being ManySortedFunction of T,C,
    Q being GeneratorSet of T such that
A3: f is_homomorphism T,C & Q = doms s & s = f||Q &
    \0(T,I) value_at(C,s) = f.I.\0(T,I) by A2,AOFA_A00:def 21;
    set o = In((the connectives of S).4, the carrier' of S);
A4: the_arity_of o = {} & the_result_sort_of o = I by Th14;
    then
    Args(o,T) = {{}} by Th21;
    then reconsider p = {} as Element of Args(o,T) by TARSKI:def 1;
    dom(f#p) = {} & dom p = {} by A4,MSUALG_3:6;
    then
A5: p = f#p;
    f.I.\0(T,I)
    = \0(C,I) by A5,A3,A4 .= 0 by AOFA_A00:55;
    hence thesis by A3;
  end;
