reserve Y for non empty set;

theorem Th36:
  for a,b being Function of Y,BOOLEAN holds 'not'( a '&' b)
  'imp' ('not' a 'or' 'not' b)=I_el(Y)
proof
  let a,b be Function of Y,BOOLEAN;
  for x being Element of Y holds ('not'( a '&' b) 'imp' ('not' a 'or'
  'not' b)).x=TRUE
  proof
    let x be Element of Y;
    ('not'( a '&' b) 'imp' ('not' a 'or' 'not' b)).x ='not' ('not'( a '&'
    b)).x 'or' ('not' a 'or' 'not' b).x by BVFUNC_1:def 8
      .=(a '&' b).x 'or' ('not' a 'or' 'not' b).x by MARGREL1:def 19
      .=(a.x '&' b.x) 'or' ('not' a 'or' 'not' b).x by MARGREL1:def 20
      .=(('not' a).x 'or' ('not' b).x) 'or' (a.x '&' b.x) by BVFUNC_1:def 4
      .=('not' a.x 'or' ('not' b).x) 'or' (a.x '&' b.x) by
MARGREL1:def 19
      .=('not' a.x 'or' 'not' b.x) 'or' (a.x '&' b.x) by
MARGREL1:def 19
      .=(('not' a.x 'or' 'not' b.x) 'or' a.x) '&' (('not' a.x 'or'
    'not' b.x) 'or' b.x) by XBOOLEAN:9
      .=(('not' a.x 'or' a.x) 'or' 'not' b.x) '&' ('not' a.x 'or' (
    'not' b.x 'or' b.x))
      .=(TRUE 'or' 'not' b.x) '&' ('not' a.x 'or' ('not' b.x 'or' b.
    x)) by XBOOLEAN:102
      .=TRUE '&' ('not' a.x 'or' TRUE) by XBOOLEAN:102
      .=TRUE;
    hence thesis;
  end;
  hence thesis by BVFUNC_1:def 11;
end;
