reserve n,n1,m,m1,k for Nat;
reserve x,X,X1 for set;
reserve g,g1,g2,t,x0,x1,x2 for Complex;
reserve s1,s2,q1,seq,seq1,seq2,seq3 for Complex_Sequence;
reserve Y for Subset of COMPLEX;
reserve f,f1,f2,h,h1,h2 for PartFunc of COMPLEX,COMPLEX;
reserve p,r,s for Real;
reserve Ns,Nseq for increasing sequence of NAT;

theorem Th36:
  f is_continuous_in x0 & f/.x0<>0 implies f^ is_continuous_in x0
proof
  assume that
A1: f is_continuous_in x0 and
A2: f/.x0<>0;
  not f/.x0 in {0c} by A2,TARSKI:def 1;
  then
A3: not x0 in f"{0c} by PARTFUN2:26;
  x0 in dom f by A1;
  then x0 in dom f \ f"{0c} by A3,XBOOLE_0:def 5;
  hence
A4: x0 in dom (f^) by CFUNCT_1:def 2;
  let s1;
  assume that
A5: rng s1 c= dom (f^) and
A6: s1 is convergent & lim s1=x0;
  dom f \ f"{0c} c= dom f & rng s1 c= dom f \ f"{0c} by A5,CFUNCT_1:def 2
,XBOOLE_1:36;
  then rng s1 c= dom f;
  then
A7: f/*s1 is convergent & f/.x0 = lim (f/*s1) by A1,A6;
  f/*s1 is non-zero by A5,Th10;
  then (f/*s1)" is convergent by A2,A7,COMSEQ_2:34;
  hence (f^)/*s1 is convergent by A5,Th11;
  thus (f^)/.x0 = (f/.x0)" by A4,CFUNCT_1:def 2
    .= lim ((f/*s1)") by A2,A5,A7,Th10,COMSEQ_2:35
    .= lim ((f^)/*s1) by A5,Th11;
end;
