reserve X for non empty set;
reserve Y for ComplexLinearSpace;
reserve f,g,h for Element of Funcs(X,the carrier of Y);
reserve a,b for Complex;
reserve u,v,w for VECTOR of CLSStruct(#Funcs(X,the carrier of Y), (FuncZero(X,
    Y)),FuncAdd(X,Y),FuncExtMult(X,Y)#);

theorem Th36:
  for X,Y be ComplexNormSpace, f, g being Point of
  C_NormSpace_of_BoundedLinearOperators(X,Y), c be Complex holds ( ||.f.|| = 0
  iff f = 0.C_NormSpace_of_BoundedLinearOperators(X,Y) ) & ||.c*f.|| = |.c.| *
  ||.f.|| & ||.f+g.|| <= ||.f.|| + ||.g.||
proof
  let X,Y be ComplexNormSpace;
  let f,g being Point of C_NormSpace_of_BoundedLinearOperators(X,Y);
  let c be Complex;
A1: now
    assume
A2: f = 0.C_NormSpace_of_BoundedLinearOperators(X,Y);
    thus ||.f.|| = 0
    proof
      reconsider g=f as Lipschitzian LinearOperator of X,Y by Def7;
      set z = (the carrier of X) --> 0.Y;
      reconsider z as Function of the carrier of X, the carrier of Y;
      consider r0 be object such that
A3:   r0 in PreNorms(g) by XBOOLE_0:def 1;
      reconsider r0 as Real by A3;
A4:   (for s be Real st s in PreNorms(g) holds s <= 0)
 implies upper_bound
      PreNorms(g) <= 0 by SEQ_4:45;
A5:   PreNorms(g) is non empty bounded_above by Th26;
A6:   z=g by A2,Th30;
A7:   now
        let r be Real;
        assume r in PreNorms(g);
        then consider t be VECTOR of X such that
A8:     r=||.g.t.|| and
        ||.t.|| <= 1;
        ||.g.t.|| = ||.0.Y.|| by A6,FUNCOP_1:7
          .= 0 by NORMSP_0:def 6;
        hence 0 <= r & r <=0 by A8;
      end;
      then 0<=r0 by A3;
      then upper_bound PreNorms(g) = 0 by A7,A5,A3,A4,SEQ_4:def 1;
      then BoundedLinearOperatorsNorm(X,Y).f =0 by Th29;
      hence thesis;
    end;
  end;
A9: ||.f+g.|| <= ||.f.|| + ||.g.||
  proof
    reconsider f1=f, g1=g, h1=f+g as Lipschitzian LinearOperator of X,Y
    by Def7;
A10: (for s be Real st s in PreNorms(h1) holds s <= ||.f.|| + ||.g
    .||) implies upper_bound PreNorms(h1) <= ||.f.|| + ||.g.|| by SEQ_4:45;
A11: now
      let t be VECTOR of X such that
A12:  ||.t.|| <= 1;
      0 <= ||.g.|| by Th32;
      then
A13:  ||.g.||*||.t.|| <= ||.g.||*1 by A12,XREAL_1:64;
      0 <= ||.f.|| by Th32;
      then ||.f.||*||.t.|| <= ||.f.||*1 by A12,XREAL_1:64;
      then
A14:  ||.f.||*||.t.|| + ||.g.||*||.t.|| <= ||.f.||*1 + ||.g.||*1 by A13,
XREAL_1:7;
A15:  ||.f1.t+g1.t.|| <=||.f1.t.||+||.g1.t.|| by CLVECT_1:def 13;
A16:  ||.g1.t.||<= ||.g.||*||.t.|| by Th31;
      ||.f1.t.||<= ||.f.||*||.t.|| by Th31;
      then ||.f1.t.||+||.g1.t.|| <= ||.f.||*||.t.|| + ||.g.||*||.t.|| by A16,
XREAL_1:7;
      then
A17:  ||.f1.t.||+||.g1.t.|| <= ||.f.|| + ||.g.|| by A14,XXREAL_0:2;
      ||.h1.t.||= ||.f1.t+g1.t.|| by Th34;
      hence ||.h1.t.|| <= ||.f.|| + ||.g.|| by A15,A17,XXREAL_0:2;
    end;
A18: now
      let r be Real;
      assume r in PreNorms(h1);
      then ex t be VECTOR of X st r=||.h1.t.|| & ||.t.|| <= 1;
      hence r <= ||.f.|| + ||.g.|| by A11;
    end;
    BoundedLinearOperatorsNorm(X,Y).(f+g) = upper_bound PreNorms(h1) by Th29;
    hence thesis by A18,A10;
  end;
A19: ||.c*f.|| = |.c.| * ||.f.||
  proof
    reconsider f1=f, h1=c*f as Lipschitzian LinearOperator of X,Y by Def7;
A20: (for s be Real st s in PreNorms(h1) holds s <= |.c.|*||.f.|| )
    implies upper_bound PreNorms(h1) <= |.c.|*||.f.|| by SEQ_4:45;
A21: now
A22:  0 <= ||.f.|| by Th32;
      let t be VECTOR of X;
      assume ||.t.|| <= 1;
      then
A23:  ||.f.||*||.t.|| <= ||.f.||*1 by A22,XREAL_1:64;
      ||.f1.t.||<= ||.f.||*||.t.|| by Th31;
      then
A24:  ||.f1.t.|| <= ||.f.|| by A23,XXREAL_0:2;
A25:  ||.c*f1.t.|| =|.c.|*||.f1.t.|| by CLVECT_1:def 13;
A26:  0<= |.c.| by COMPLEX1:46;
      ||.h1.t.||= ||.c*f1.t.|| by Th35;
      hence ||.h1.t.|| <= |.c.|*||.f.|| by A25,A24,A26,XREAL_1:64;
    end;
A27: now
      let r be Real;
      assume r in PreNorms(h1);
      then ex t be VECTOR of X st r=||.h1.t.|| & ||.t.|| <= 1;
      hence r <= |.c.|*||.f.|| by A21;
    end;
A28: now
      per cases;
      case
A29:    c <> 0c;
A30:    now
A31:      0 <= ||.c*f.|| by Th32;
          let t be VECTOR of X;
          assume ||.t.|| <= 1;
          then
A32:      ||.c*f.||*||.t.|| <= ||.c*f.||*1 by A31,XREAL_1:64;
          ||.h1.t.||<= ||.c*f.||*||.t.|| by Th31;
          then
A33:      ||.h1.t.|| <= ||.c*f.|| by A32,XXREAL_0:2;
          h1.t=c*f1.t by Th35;
          then
A34:      c"*h1.t =( c"* c)*f1.t by CLVECT_1:def 4
            .=1r*f1.t by A29,COMPLEX1:def 4,XCMPLX_0:def 7
            .=f1.t by CLVECT_1:def 5;
A35:      |.c".| =|.c.|" by COMPLEX1:66;
A36:      0<= |.c".| by COMPLEX1:46;
          ||.c"*h1.t.|| =|.c".|*||.h1.t.|| by CLVECT_1:def 13;
          hence ||.f1.t.|| <= |.c.|"*||.c*f.|| by A34,A33,A36,A35,XREAL_1:64;
        end;
A37:    now
          let r be Real;
          assume r in PreNorms(f1);
          then ex t be VECTOR of X st r=||.f1.t.|| & ||.t.|| <= 1;
          hence r <= |.c.|"*||.c*f.|| by A30;
        end;
A38:    (for s be Real st s in PreNorms(f1) holds s <= |.c.|"*||.c
        *f.|| ) implies upper_bound PreNorms(f1) <= |.c.|"*||.c*f.||
        by SEQ_4:45;
A39:    0 <= |.c.| by COMPLEX1:46;
        BoundedLinearOperatorsNorm(X,Y).(f) = upper_bound PreNorms(f1) by Th29;
        then ||.f.|| <=|.c.|"*||.c*f.|| by A37,A38;
        then |.c.|*||.f.|| <=|.c.|*(|.c.|"*||.c*f.||) by A39,XREAL_1:64;
        then
A40:    |.c.|*||.f.|| <=(|.c.|*|.c.|")*||.c*f.||;
        |.c.| <>0 by A29,COMPLEX1:47;
        then |.c.|*||.f.|| <=1*||.c*f.|| by A40,XCMPLX_0:def 7;
        hence |.c.|* ||.f.|| <=||.c*f.||;
      end;
      case
A41:    c = 0c;
        reconsider fz=f as VECTOR of C_VectorSpace_of_BoundedLinearOperators(X
        ,Y);
        c*f =Mult_(BoundedLinearOperators(X,Y),
        C_VectorSpace_of_LinearOperators(X,Y)).[c,f] by CLVECT_1:def 1
          .=c*fz by CLVECT_1:def 1
          .=0.C_VectorSpace_of_BoundedLinearOperators(X,Y) by A41,CLVECT_1:1
          .=0.C_NormSpace_of_BoundedLinearOperators(X,Y);
        hence thesis by A41,Th33,COMPLEX1:44;
      end;
    end;
    BoundedLinearOperatorsNorm(X,Y).(c*f) = upper_bound PreNorms(h1) by Th29;
    then ||.c*f.|| <= |.c.|*||.f.|| by A27,A20;
    hence thesis by A28,XXREAL_0:1;
  end;
  now
    reconsider g=f as Lipschitzian LinearOperator of X,Y by Def7;
    set z = (the carrier of X) --> 0.Y;
    reconsider z as Function of the carrier of X, the carrier of Y;
    assume
A42: ||.f.|| = 0;
    now
      let t be VECTOR of X;
      ||.g.t.|| <= ||.f.|| *||.t.|| by Th31;
      then ||.g.t.|| = 0 by A42,CLVECT_1:105;
      hence g.t =0.Y by NORMSP_0:def 5
        .=z.t by FUNCOP_1:7;
    end;
    then g=z by FUNCT_2:63;
    hence f=0.C_NormSpace_of_BoundedLinearOperators(X,Y) by Th30;
  end;
  hence thesis by A1,A19,A9;
end;
