reserve a,b,c,d,e for Real;
reserve X,Y for set,
          Z for non empty set,
          r for Real,
          s for ExtReal,
          A for Subset of REAL,
          f for real-valued Function;
reserve I for non empty closed_interval Subset of REAL,
       TD for tagged_division of I,
        D for Division of I,
        T for Element of set_of_tagged_Division(D),
        f for PartFunc of I,REAL;
reserve f for Function of I,REAL;
reserve f,g for HK-integrable Function of I,REAL,
          r for Real;

theorem Th33:
  for i being Nat st i in dom TD holds
  (tagged_volume(f + g,TD)).i
    = f.((tagged_of TD).i) * vol(divset(division_of TD,i))
      + g.((tagged_of TD).i) * vol(divset(division_of TD,i))
  proof
    let i be Nat;
    assume
A1: i in dom TD;
    consider D be Division of I,
             T be Element of set_of_tagged_Division(D) such that
A2: tagged_of TD = T and
A3: TD = [D,T] by Def2;
A4: i in dom D by A1,Th20,A3;
A5: dom T = Seg len tagged_of TD by A2,FINSEQ_1:def 3
         .= Seg len division_of TD by Th21
         .= Seg len D by A3,Th20
         .= dom D by FINSEQ_1:def 3;
    rng T c= I by Th22;
    then reconsider c = (tagged_of TD).i as Element of I
      by A2,A4,A5,FUNCT_1:3;
    (tagged_volume(f + g,TD)).i = (f + g).c * vol(divset(division_of TD,i))
                                  by A1,Def4
                               .= (f.c + g.c) * vol(divset(division_of TD,i))
                                  by VALUED_1:1;
    hence thesis;
  end;
