reserve D for non empty set,
  i,j,k,l for Nat,
  n for Nat,
  x for set,
  a,b,c,r,r1,r2 for Real,
  p,q for FinSequence of REAL,
  MR,MR1 for Matrix of REAL;

theorem Th36:
  for M being Matrix of D for p being FinSequence of D* st len p =
len M & p.1 = M.1 & (for k st k >= 1 & k < len M holds p.(k+1) = (p.k) ^ M.(k+1
)) holds for i,j st [i,j] in Indices M holds (i-1)*(width M)+j in dom(p.(len M)
  ) & M*(i,j) = (p.(len M)).((i-1)*(width M)+j)
proof
  let M be Matrix of D;
  let p be FinSequence of D* such that
A1: len p = len M and
A2: p.1 = M.1 and
A3: for k st k >= 1 & k < len M holds p.(k+1) = (p.k) ^ M.(k+1);
  let i,j such that
A4: [i,j] in Indices M;
A5: (i-1)*(width M)+j in dom(p.i) by A1,A2,A3,A4,Th35;
A6: M*(i,j) = (p.i).((i-1)*(width M)+j) by A1,A2,A3,A4,Th35;
A7: i in Seg len M by A4,MATRPROB:12;
  then
A8: len M <> 0;
A9: i <= len M by A7,FINSEQ_1:1;
  len M >= 1 by A8,NAT_1:14;
  then len M in Seg len p by A1,FINSEQ_1:1;
  then
A10: len M in dom p by FINSEQ_1:def 3;
A11: i in dom p by A1,A7,FINSEQ_1:def 3;
  then dom(p.i) c= dom(p.(len M)) by A1,A2,A3,A9,A10,Th30;
  hence thesis by A1,A2,A3,A9,A11,A10,A5,A6,Th33;
end;
