reserve y for set;
reserve x,a,b,c for Real;
reserve n for Element of NAT;
reserve Z for open Subset of REAL;
reserve f,f1,f2 for PartFunc of REAL,REAL;

theorem
  Z c= dom ((2(#)(( #R (1/2))*f))) & f=f1+f2 & f2=#Z 2 & (for x st x in
  Z holds f1.x=x & f.x>0) implies 2(#)(( #R (1/2))*f) is_differentiable_on Z &
for x st x in Z holds ((2(#)(( #R (1/2))*f))`|Z).x =(2*x+1)*(x |^2+x) #R (-1/2)
proof
  assume that
A1: Z c= dom ((2(#)(( #R (1/2))*f))) and
A2: f=f1+f2 and
A3: f2=#Z 2 and
A4: for x st x in Z holds f1.x=x & f.x>0;
A5: for x st x in Z holds f1.x=0+1*x by A4;
A6: f2=1(#)f2 by RFUNCT_1:21;
A7: Z c= dom (( #R (1/2))*f) by A1,VALUED_1:def 5;
  then for y being object st y in Z holds y in dom f by FUNCT_1:11;
  then
A8: Z c= dom (f1+1(#)f2) by A2,A6,TARSKI:def 3;
  then
A9: f1+f2 is_differentiable_on Z by A3,A6,A5,Th12;
  now
    let x;
    assume x in Z;
    then f is_differentiable_in x & f.x >0 by A2,A4,A9,FDIFF_1:9;
    hence ( #R (1/2))*f is_differentiable_in x by TAYLOR_1:22;
  end;
  then
A10: ( #R (1/2))*f is_differentiable_on Z by A7,FDIFF_1:9;
A11: for x st x in Z holds ((f1+f2)`|Z).x = 1+2*1*x by A3,A6,A8,A5,Th12;
  for x st x in Z holds ((2(#)(( #R (1/2))*f))`|Z).x =(2*x+1)*(x |^2+x)
  #R (-1/2)
  proof
    let x;
    assume
A12: x in Z;
    then
A13: f is_differentiable_in x & f.x >0 by A2,A4,A9,FDIFF_1:9;
    x in dom (f1+f2) by A2,A7,A12,FUNCT_1:11;
    then
A14: ( f1+f2).x=f1.x + f2.x by VALUED_1:def 1
      .=x +(f2.x) by A4,A12
      .=x +(x #Z 2) by A3,TAYLOR_1:def 1
      .=x +x |^2 by PREPOWER:36;
    ((2(#)(( #R (1/2))*f))`|Z).x =2*diff((( #R (1/2))*f),x) by A1,A10,A12,
FDIFF_1:20
      .=2*((1/2)*( ( f.x) #R (1/2-1)) * diff(f,x)) by A13,TAYLOR_1:22
      .=2*((1/2)*( ( f.x) #R (1/2-1))*(f`|Z).x) by A2,A9,A12,FDIFF_1:def 7
      .=2*(1/2)*( ( f.x) #R (1/2-1))*(f`|Z).x
      .=(2*x+1)* (x |^2+x) #R (-1/2) by A2,A11,A12,A14;
    hence thesis;
  end;
  hence thesis by A1,A10,FDIFF_1:20;
end;
