reserve x,a,b,c for Real,
  n for Nat,
  Z for open Subset of REAL,
  f, f1,f2 for PartFunc of REAL,REAL;

theorem
  Z c= dom (cosec*sin) implies cosec*sin is_differentiable_on Z & for x
  st x in Z holds ((cosec*sin)`|Z).x = -cos.x*cos.(sin.x)/(sin.(sin.x))^2
proof
  assume
A1: Z c= dom (cosec*sin);
A2: for x st x in Z holds sin.(sin.x)<>0
  proof
    let x;
    assume x in Z;
    then sin.x in dom cosec by A1,FUNCT_1:11;
    hence thesis by RFUNCT_1:3;
  end;
A3: for x st x in Z holds cosec*sin is_differentiable_in x
  proof
    let x;
    assume x in Z;
    then sin.(sin.x)<>0 by A2;
    then sin is_differentiable_in x & cosec is_differentiable_in sin.x by Th2,
SIN_COS:64;
    hence thesis by FDIFF_2:13;
  end;
  then
A4: cosec*sin is_differentiable_on Z by A1,FDIFF_1:9;
  for x st x in Z holds ((cosec*sin)`|Z).x = -cos.x*cos.(sin.x)/(sin.(sin
  .x))^2
  proof
    let x;
    assume
A5: x in Z;
    then
A6: sin.(sin.x)<>0 by A2;
    then sin is_differentiable_in x & cosec is_differentiable_in sin.x by Th2,
SIN_COS:64;
    then diff(cosec*sin,x) = diff(cosec, sin.x)*diff(sin,x) by FDIFF_2:13
      .=(-cos.(sin.x)/(sin.(sin.x))^2) * diff(sin,x) by A6,Th2
      .=cos.x*(-cos.(sin.x)/(sin.(sin.x))^2) by SIN_COS:64;
    hence thesis by A4,A5,FDIFF_1:def 7;
  end;
  hence thesis by A1,A3,FDIFF_1:9;
end;
