
theorem KrSet:
for F being Field
for P being finite Subset of the carrier of Polynom-Ring F
ex E being FieldExtension of F
st for p being non constant Element of the carrier of Polynom-Ring F
st p in P holds p is_with_roots_in E
proof
let F be Field;
let P be finite Subset of the carrier of Polynom-Ring F;
defpred P[Nat] means
 for F being Field
 for P being finite Subset of the carrier of Polynom-Ring F
 st card P = $1
 ex E being FieldExtension of F
 st for p being non constant Element of the carrier of Polynom-Ring F
  st p in P holds p is_with_roots_in E;
IA: P[0]
    proof
    now let F be Field,
            P be finite Subset of the carrier of Polynom-Ring F;
      assume A: card P = 0;
      reconsider E = F as FieldExtension of F by FIELD_4:6;
      for p being non constant Element of the carrier of Polynom-Ring F
         st p in P holds p is_with_roots_in E by A;
      hence ex E being FieldExtension of F
      st for p being non constant Element of the carrier of Polynom-Ring F
      st p in P holds p is_with_roots_in E;
      end;
    hence P[0];
    end;
IS: now let k be Nat;
    assume A: P[k];
    now let F be Field,
            P be finite Subset of the carrier of Polynom-Ring F;
      assume AS: card P = k+1;
      set p = the Element of P;
      set B = P \ { p };
      P <> {} by AS; then
      B3: p in P & p in {p} by TARSKI:def 1; then
      B1: not(p in B) by XBOOLE_0:def 5;
      { p } c= P by TARSKI:def 1,B3; then
      B2: P = B \/ { p } by FIELD_5:1; then
      card P = card B + 1 by B1,CARD_2:41; then
      consider K being FieldExtension of F such that
      C: for p being non constant Element of the carrier of Polynom-Ring F
         st p in B holds p is_with_roots_in K by A,AS;
      reconsider p as Element of the carrier of Polynom-Ring F by B3;
      the carrier of Polynom-Ring F c= the carrier of Polynom-Ring K
         by FIELD_4:10; then
      reconsider p1 = p as Element of the carrier of Polynom-Ring K;
      per cases;
      suppose E0: p1 is constant;
        now let q be non constant Element of the carrier of Polynom-Ring F;
          H: deg q > 0 by RING_4:def 4;
          assume E1: q in P;
          q <> p by H,E0,FIELD_4:20;
          then not q in { p } by TARSKI:def 1;
          then q in B by B2,E1,XBOOLE_0:def 3;
          hence q is_with_roots_in K by C;
          end;
        hence ex E being FieldExtension of F
        st for p being non constant Element of the carrier of Polynom-Ring F
        st p in P holds p is_with_roots_in E;
        end;
      suppose p1 is non constant; then
        reconsider p1 as non constant Element of the carrier of Polynom-Ring K;
        consider E being FieldExtension of K such that
        D: p1 is_with_roots_in E by FIELD_5:30;
        E: K is Subring of E by FIELD_4:def 1;
        reconsider E as K-extending FieldExtension of F;
        now let q be non constant Element of the carrier of Polynom-Ring F;
        assume E1: q in P;
        per cases;
        suppose E2: q = p1;
          consider a being Element of E such that
          E3: a is_a_root_of p1,E by D,FIELD_4:def 3;
          E4: Ext_eval(p1,a) = 0.E by E3,FIELD_4:def 2;
          Ext_eval(p1,a) = Ext_eval(p,a) by FIELD_7:15;
          hence q is_with_roots_in E by E2,E4,FIELD_4:def 2,FIELD_4:def 3;
          end;
        suppose q <> p1;
          then not q in { p } by TARSKI:def 1;
          then q in B by E1,B2,XBOOLE_0:def 3;
          then consider a being Element of K such that
          E3: a is_a_root_of q,K by C,FIELD_4:def 3;
          the carrier of K c= the carrier of E by E,C0SP1:def 3; then
          reconsider a1 = a as Element of E;
          Ext_eval(q,a1) = Ext_eval(q,a) by FIELD_7:14
                        .= 0.K by E3,FIELD_4:def 2
                        .= 0.E by E,C0SP1:def 3;
          hence q is_with_roots_in E by FIELD_4:def 2,FIELD_4:def 3;
          end;
        end;
      hence ex E being FieldExtension of F
       st for p being non constant Element of the carrier of Polynom-Ring F
       st p in P holds p is_with_roots_in E;
      end;
      end;
    hence P[k+1];
    end;
I: for k being Nat holds P[k] from NAT_1:sch 2(IA,IS);
consider n being Nat such that H: card P = n;
thus thesis by I,H;
end;
