reserve T   for TopSpace,
        A,B for Subset of T;
reserve NT,NTX,NTY for NTopSpace,
        A,B        for Subset of NT,
        O          for open Subset of NT,
        a          for Point of NT,
        XA         for Subset of NTX,
        YB         for Subset of NTY,
        x          for Point of NTX,
        y          for Point of NTY,
        f          for Function of NTX,NTY,
        fc         for continuous Function of NTX,NTY;

theorem Th36:
  A is a_neighborhood of B implies
  NTop2Top A is a_neighborhood of NTop2Top B
  proof
    assume
A1: A is a_neighborhood of B;
    reconsider T = NTop2Top NT as TopSpace;
    reconsider TA = NTop2Top A, TB = NTop2Top B as Subset of T;
    per cases;
    suppose B is non empty;
      then consider O be open Subset of NT such that
A2:   B c= O and
A3:   O c= A by A1,FINTOPO7:16;
      reconsider O9 = O as open Subset of T by Lm9;
      O9 c= Int TA by A3,TOPS_1:24;
      then TB c= Int TA by A2;
      hence thesis by CONNSP_2:def 2;
    end;
    suppose B is empty;
      then TB c= Int TA;
      hence thesis by CONNSP_2:def 2;
    end;
  end;
