
theorem TrF160:
for F being Function of REAL,REAL, a,b,c,d being Real, i be Integer st
a<>0 & i<>0 & for x be Real holds F.x= max(0,min(1, c*sin(a*x+b)+d))
holds
F is (2 * PI)/a * i -periodic
proof
 let F be Function of REAL,REAL;
 let a,b,c,d be Real;
 let i be Integer;
 assume A0: a<>0 & i<>0;
 assume A2: for x be Real holds F.x= max(0,min(1, c*sin(a*x+b)+d));
 for x being Real st x in dom F holds
 x + (2 * PI)/a * i in dom F & x - (2 * PI)/a * i in dom F
 & F . x = F . (x + (2 * PI)/a * i)
 proof
  let x be Real;
  assume x in dom F;
A3A:  x + (2 * PI)/a * i in REAL
  & x - (2 * PI)/a * i in REAL by XREAL_0:def 1;
  S1:sin is (2 * PI) * i -periodic by FUNCT_9:21,A0;
SS:  a*x+b in dom sin by SIN_COS:24, XREAL_0:def 1;
  F . (x + (2 * PI)/a * i)
   = max(0,min(1, c*sin(a*(x + (2 * PI)/a * i)+b)+d)) by A2
   .= max(0,min(1, c*sin(a*x + a*((2 * PI)/a) * i+b)+d))
   .= max(0,min(1, c*sin(a*x + a/a*(2 * PI) * i+b)+d)) by XCMPLX_1:75
   .= max(0,min(1, c*sin(a*x + 1*(2 * PI) * i+b)+d)) by XCMPLX_1:60,A0
   .= max(0,min(1, c*sin.((a*x + b) + (2 * PI) * i)+d)) by SIN_COS:def 17
   .= max(0,min(1, c*sin.(a*x + b)+d)) by FUNCT_9:1,SS,S1
   .= max(0,min(1, c*sin(a*x + b)+d)) by SIN_COS:def 17;
  hence thesis by FUNCT_2:def 1,A3A,A2;
 end;
 hence thesis by FUNCT_9:1,A0;
end;
