reserve X,Y for set;
reserve R for domRing-like commutative Ring;
reserve c for Element of R;
reserve R for gcdDomain;

theorem Th36:
  for Amp being AmpleSet of R for a,b,c being Element of R holds
  gcd(a * c,b * c,Amp) is_associated_to (c * gcd(a,b,Amp))
proof
  let Amp be AmpleSet of R;
  let A,B,C be Element of R;
  now
    per cases;
    case
A1:   C <> 0.R;
      set D = gcd(A,B,Amp);
      now
        per cases;
        case
A2:       D <> 0.R;
          set E = gcd((A * C),(B * C),Amp);
A3:       E divides B * C by Def12;
          D divides B by Def12;
          then
A4:       C * D divides B * C by Th5;
          D divides A by Def12;
          then C * D divides A * C by Th5;
          then C * D divides gcd((A * C),(B * C),Amp) by A4,Def12;
          then consider F being Element of R such that
A5:       E = (C * D) * F;
A6:       E divides A * C by Def12;
          (D * F) divides A & (D * F) divides B
          proof
            consider G being Element of R such that
A7:         ((C * D) * F) * G = A * C by A5,A6;
            (C * (D * F)) * G = C * A by A7,GROUP_1:def 3;
            then
A8:         (C * (D * F)) divides C * A;
            consider G being Element of R such that
A9:         ((C * D) * F) * G = B * C by A5,A3;
            (C * (D * F)) * G = C * B by A9,GROUP_1:def 3;
            then (C * (D * F)) divides C * B;
            hence thesis by A1,A8,Th15;
          end;
          then
A10:      D * F divides D by Def12;
          D = D * 1.R;
          then F divides 1.R by A2,A10,Th15;
          then ex y being Element of R st 1.R = F * y;
          then F is unital;
          hence thesis by A5,Th18;
        end;
        case
A11:      D = 0.R;
          then
A12:      C * gcd(A,B,Amp) = 0.R;
          A = 0.R & B = 0.R by A11,Th33;
          then gcd((A * C),(B * C),Amp) = gcd(0.R,(0.R * C),Amp)
            .= gcd(0.R,0.R,Amp)
            .= C * gcd(A,B,Amp) by A12,Th31;
          hence thesis;
        end;
      end;
      hence thesis;
    end;
    case
A13:  C = 0.R;
      then A * C = 0.R & B * C = 0.R;
      then gcd((A * C),(B * C),Amp) = 0.R by Th31
        .= C * gcd(A,B,Amp) by A13;
      hence thesis;
    end;
  end;
  hence thesis;
end;
