reserve x, y for set;
reserve D for non empty set;
reserve UN for Universe;
reserve C for Category;
reserve O for non empty Subset of the carrier of C;
reserve G,H for AddGroup;
reserve V for Group_DOMAIN;

theorem Th35:
  for f,g being (Morphism of GroupCat(UN)),
      f9,g9 being Element of Morphs(GroupObjects(UN)) st f = f9 & g = g9
 holds
  (dom g = cod f iff dom g9 = cod f9) &
  (dom g = cod f iff [g9,f9] in dom comp(GroupObjects(UN))) &
  (dom g = cod f implies g(*)f = g9*f9) &
  (dom f = dom g iff dom f9 = dom g9) &
  (cod f = cod g iff cod f9 = cod g9)
proof
  set C = GroupCat(UN), V = GroupObjects(UN);
  set X = Morphs(V);
  let f,g be Morphism of C;
  let f9,g9 be Element of X;
  assume that
A1: f = f9 and
A2: g = g9;
A3: cod f = cod f9 by A1,Def26;
  hence dom g = cod f iff dom g9 = cod f9 by A2,Def25;
  dom g = dom g9 by A2,Def25;
  hence
A4: dom g = cod f iff [g9,f9] in dom comp(V) by A3,Def27;
  thus dom g = cod f implies g(*)f = g9*f9
  proof
    assume
A5: dom g = cod f;
    then [g,f] in dom (the Comp of C) by Th33;
    hence g(*)f = (comp(V)).(g9,f9) by A1,A2,CAT_1:def 1
      .= g9*f9 by A4,A5,Def27;
  end;
  dom f = dom f9 by A1,Def25;
  hence dom f = dom g iff dom f9 = dom g9 by A2,Def25;
  cod g = cod g9 by A2,Def26;
  hence thesis by A1,Def26;
end;
