reserve a for Real;
reserve p,q for Point of TOP-REAL 2;

theorem Th36:
  for sn being Real, D being non empty Subset of TOP-REAL 2 st -1<
  sn & sn<1 & D`={0.TOP-REAL 2} holds ex h being Function of (TOP-REAL 2)|D,(
  TOP-REAL 2)|D st h=(sn-FanMorphW)|D & h is continuous
proof
  (|[0,1]|)`1=0 & (|[0,1]|)`2=1 by EUCLID:52;
  then
A1: |[0,1]| in {p where p is Point of TOP-REAL 2: p`1<=0 & p<>0.TOP-REAL 2}
  by JGRAPH_2:3;
  set Y1=|[0,1]|;
  defpred P[Point of TOP-REAL 2] means $1`1<=0;
  reconsider B0= {0.TOP-REAL 2} as Subset of TOP-REAL 2;
  let sn be Real,D be non empty Subset of TOP-REAL 2;
  assume that
A2: -1<sn & sn<1 and
A3: D`={0.TOP-REAL 2};
A4: the carrier of ((TOP-REAL 2)|D)=D by PRE_TOPC:8;
A5: D =(B0)` by A3
    .=(NonZero TOP-REAL 2) by SUBSET_1:def 4;
  {p: P[p] & p<>0.TOP-REAL 2} c= the carrier of (TOP-REAL 2)|D from
  InclSub(A5);
  then reconsider
  K0={p:p`1<=0 & p<>0.TOP-REAL 2} as non empty Subset of (TOP-REAL
  2)|D by A1;
A6: K0 =the carrier of ((TOP-REAL 2)|D)|K0 by PRE_TOPC:8;
A7: the carrier of ((TOP-REAL 2)|D) =D by PRE_TOPC:8;
A8: rng ((sn-FanMorphW)|K0) c= the carrier of ((TOP-REAL 2)|D)|K0
  proof
    let y be object;
    assume y in rng ((sn-FanMorphW)|K0);
    then consider x being object such that
A9: x in dom ((sn-FanMorphW)|K0) and
A10: y=((sn-FanMorphW)|K0).x by FUNCT_1:def 3;
    x in (dom (sn-FanMorphW)) /\ K0 by A9,RELAT_1:61;
    then
A11: x in K0 by XBOOLE_0:def 4;
    K0 c= the carrier of TOP-REAL 2 by A7,XBOOLE_1:1;
    then reconsider p=x as Point of TOP-REAL 2 by A11;
    (sn-FanMorphW).p=y by A10,A11,FUNCT_1:49;
    then y in K0 by A2,A11,Th34;
    hence thesis by PRE_TOPC:8;
  end;
A12: K0 c= (the carrier of TOP-REAL 2)
  proof
    let z be object;
    assume z in K0;
    then ex p8 being Point of TOP-REAL 2 st p8=z & p8`1<=0 & p8 <>0.TOP-REAL 2;
    hence thesis;
  end;
  Y1`1=0 & Y1`2=1 by EUCLID:52;
  then
A13: Y1 in {p where p is Point of TOP-REAL 2: p`1>=0 & p<>0.TOP-REAL 2} by
JGRAPH_2:3;
A14: the carrier of ((TOP-REAL 2)|D) = (NonZero TOP-REAL 2) by A5,PRE_TOPC:8;
  defpred P[Point of TOP-REAL 2] means $1`1>=0;
  {p: P[p] & p<>0.TOP-REAL 2} c= the carrier of (TOP-REAL 2)|D from
  InclSub(A5);
  then reconsider
  K1={p: p`1>=0 & p<>0.TOP-REAL 2} as non empty Subset of (TOP-REAL
  2)|D by A13;
A15: K0 is closed & K1 is closed by A5,Th29,Th31;
  dom ((sn-FanMorphW)|K0)= dom ((sn-FanMorphW)) /\ K0 by RELAT_1:61
    .=((the carrier of TOP-REAL 2)) /\ K0 by FUNCT_2:def 1
    .=K0 by A12,XBOOLE_1:28;
  then reconsider f=(sn-FanMorphW)|K0 as Function of ((TOP-REAL 2)|D)|K0, ((
  TOP-REAL 2)|D) by A6,A8,FUNCT_2:2,XBOOLE_1:1;
A16: K1=the carrier of ((TOP-REAL 2)|D)|K1 by PRE_TOPC:8;
A17: rng ((sn-FanMorphW)|K1) c= the carrier of ((TOP-REAL 2)|D)|K1
  proof
    let y be object;
    assume y in rng ((sn-FanMorphW)|K1);
    then consider x being object such that
A18: x in dom ((sn-FanMorphW)|K1) and
A19: y=((sn-FanMorphW)|K1).x by FUNCT_1:def 3;
    x in (dom (sn-FanMorphW)) /\ K1 by A18,RELAT_1:61;
    then
A20: x in K1 by XBOOLE_0:def 4;
    K1 c= the carrier of TOP-REAL 2 by A7,XBOOLE_1:1;
    then reconsider p=x as Point of TOP-REAL 2 by A20;
    (sn-FanMorphW).p=y by A19,A20,FUNCT_1:49;
    then y in K1 by A2,A20,Th35;
    hence thesis by PRE_TOPC:8;
  end;
A21: K1 c= (the carrier of TOP-REAL 2)
  proof
    let z be object;
    assume z in K1;
    then ex p8 being Point of TOP-REAL 2 st p8=z & p8`1>=0 & p8 <>0.TOP-REAL 2;
    hence thesis;
  end;
  dom ((sn-FanMorphW)|K1)= dom ((sn-FanMorphW)) /\ K1 by RELAT_1:61
    .=((the carrier of TOP-REAL 2)) /\ K1 by FUNCT_2:def 1
    .=K1 by A21,XBOOLE_1:28;
  then reconsider g=(sn-FanMorphW)|K1 as Function of ((TOP-REAL 2)|D)|K1, ((
  TOP-REAL 2)|D) by A16,A17,FUNCT_2:2,XBOOLE_1:1;
A22: K1=[#](((TOP-REAL 2)|D)|K1) by PRE_TOPC:def 5;
A23: D c= K0 \/ K1
  proof
    let x be object;
    assume
A24: x in D;
    then reconsider px=x as Point of TOP-REAL 2;
    not x in {0.TOP-REAL 2} by A5,A24,XBOOLE_0:def 5;
    then px`1<=0 & px<>0.TOP-REAL 2 or px`1>=0 & px<>0.TOP-REAL 2 by
TARSKI:def 1;
    then x in K0 or x in K1;
    hence thesis by XBOOLE_0:def 3;
  end;
A25: dom f=K0 by A6,FUNCT_2:def 1;
A26: K0=[#](((TOP-REAL 2)|D)|K0) by PRE_TOPC:def 5;
A27: for x be object st x in ([#](((TOP-REAL 2)|D)|K0)) /\ ([#] ((((TOP-REAL
  2)|D)|K1))) holds f.x = g.x
  proof
    let x be object;
    assume
A28: x in ([#]((((TOP-REAL 2)|D)|K0))) /\ ([#] ((((TOP-REAL 2)|D)|K1)) );
    then x in K0 by A26,XBOOLE_0:def 4;
    then f.x=(sn-FanMorphW).x by FUNCT_1:49;
    hence thesis by A22,A28,FUNCT_1:49;
  end;
  D= [#]((TOP-REAL 2)|D) by PRE_TOPC:def 5;
  then
A29: ([#](((TOP-REAL 2)|D)|K0)) \/ ([#](((TOP-REAL 2)|D)|K1)) = [#]((
  TOP-REAL 2)|D) by A26,A22,A23,XBOOLE_0:def 10;
A30: f is continuous & g is continuous by A2,A5,Th30,Th32;
  then consider h being Function of (TOP-REAL 2)|D,(TOP-REAL 2)|D such that
A31: h= f+*g and
  h is continuous by A26,A22,A29,A15,A27,JGRAPH_2:1;
A32: dom h=the carrier of ((TOP-REAL 2)|D) by FUNCT_2:def 1;
A33: dom g=K1 by A16,FUNCT_2:def 1;
  K0=[#](((TOP-REAL 2)|D)|K0) & K1=[#](((TOP-REAL 2)|D)|K1) by PRE_TOPC:def 5;
  then
A34: f tolerates g by A27,A25,A33,PARTFUN1:def 4;
A35: for x being object st x in dom h holds h.x=((sn-FanMorphW)|D).x
  proof
    let x be object;
    assume
A36: x in dom h;
    then reconsider p=x as Point of TOP-REAL 2 by A14,XBOOLE_0:def 5;
A37: x in D`` by A32,A36,PRE_TOPC:8;
    not x in {0.TOP-REAL 2} by A14,A36,XBOOLE_0:def 5;
    then
A38: x <>0.TOP-REAL 2 by TARSKI:def 1;
    per cases;
    suppose
A39:  x in K0;
A40:  (sn-FanMorphW)|D.p=(sn-FanMorphW).p by A37,FUNCT_1:49
        .=f.p by A39,FUNCT_1:49;
      h.p=(g+*f).p by A31,A34,FUNCT_4:34
        .=f.p by A25,A39,FUNCT_4:13;
      hence thesis by A40;
    end;
    suppose
      not x in K0;
      then not p`1<=0 by A38;
      then
A41:  x in K1 by A38;
      (sn-FanMorphW)|D.p=(sn-FanMorphW).p by A37,FUNCT_1:49
        .=g.p by A41,FUNCT_1:49;
      hence thesis by A31,A33,A41,FUNCT_4:13;
    end;
  end;
  dom (sn-FanMorphW)=(the carrier of (TOP-REAL 2)) by FUNCT_2:def 1;
  then dom ((sn-FanMorphW)|D)=(the carrier of (TOP-REAL 2))/\ D by RELAT_1:61
    .=the carrier of ((TOP-REAL 2)|D) by A4,XBOOLE_1:28;
  then f+*g=(sn-FanMorphW)|D by A31,A32,A35,FUNCT_1:2;
  hence thesis by A26,A22,A29,A30,A15,A27,JGRAPH_2:1;
end;
