reserve n for Nat;

theorem Th36:
  for C be Simple_closed_curve for i,j,k be Nat st 1 <
j & j <= k & k < len Gauge(C,n) & 1 <= i & i <= width Gauge(C,n) & LSeg(Gauge(C
  ,n)*(j,i),Gauge(C,n)*(k,i)) /\ L~Upper_Seq(C,n) = {Gauge(C,n)*(j,i)} & LSeg(
  Gauge(C,n)*(j,i),Gauge(C,n)*(k,i)) /\ L~Lower_Seq(C,n) = {Gauge(C,n)*(k,i)}
  holds LSeg(Gauge(C,n)*(j,i),Gauge(C,n)*(k,i)) meets Lower_Arc C
proof
  let C be Simple_closed_curve;
  let i,j,k be Nat;
  set Ga = Gauge(C,n);
  set US = Upper_Seq(C,n);
  set LS = Lower_Seq(C,n);
  set LA = Lower_Arc C;
  set Wmin = W-min L~Cage(C,n);
  set Emax = E-max L~Cage(C,n);
  set Wbo = W-bound L~Cage(C,n);
  set Ebo = E-bound L~Cage(C,n);
  set Gij = Ga*(j,i);
  set Gik = Ga*(k,i);
  assume that
A1: 1 < j and
A2: j <= k and
A3: k < len Ga and
A4: 1 <= i and
A5: i <= width Ga and
A6: LSeg(Gij,Gik) /\ L~US = {Gij} and
A7: LSeg(Gij,Gik) /\ L~LS = {Gik} and
A8: LSeg(Gij,Gik) misses LA;
  Gik in {Gik} by TARSKI:def 1;
  then
A9: Gik in L~LS by A7,XBOOLE_0:def 4;
  Gij in {Gij} by TARSKI:def 1;
  then
A10: Gij in L~US by A6,XBOOLE_0:def 4;
A11: len Ga = width Ga by JORDAN8:def 1;
A12: j <> k by A1,A3,A4,A5,A9,A10,Th27;
A13: j < width Ga by A2,A3,A11,XXREAL_0:2;
A14: 1 < k by A1,A2,XXREAL_0:2;
A15: k < width Ga by A3,JORDAN8:def 1;
A16: [j,i] in Indices Ga by A1,A4,A5,A11,A13,MATRIX_0:30;
A17: [k,i] in Indices Ga by A3,A4,A5,A14,MATRIX_0:30;
  set go = R_Cut(US,Gij);
  set co = L_Cut(LS,Gik);
A18: len US >= 3 by JORDAN1E:15;
  then len US >= 1 by XXREAL_0:2;
  then 1 in dom US by FINSEQ_3:25;
  then
A19: US.1 = US/.1 by PARTFUN1:def 6
    .= Wmin by JORDAN1F:5;
A20: Wmin`1 = Wbo by EUCLID:52
    .= Ga*(1,i)`1 by A4,A5,A11,JORDAN1A:73;
  len Ga >= 4 by JORDAN8:10;
  then
A21: len Ga >= 1 by XXREAL_0:2;
  then
A22: [1,k] in Indices Ga by A14,A15,MATRIX_0:30;
A23: [1,i] in Indices Ga by A4,A5,A21,MATRIX_0:30;
  then
A24: Gij <> US.1 by A1,A16,A19,A20,JORDAN1G:7;
  then reconsider go as being_S-Seq FinSequence of TOP-REAL 2 by A10,JORDAN3:35
;
A25: len LS >= 1+2 by JORDAN1E:15;
  then
A26: len LS >= 1 by XXREAL_0:2;
  then
A27: 1 in dom LS by FINSEQ_3:25;
  len LS in dom LS by A26,FINSEQ_3:25;
  then
A28: LS.len LS = LS/.len LS by PARTFUN1:def 6
    .= Wmin by JORDAN1F:8;
  Wmin`1 = Wbo by EUCLID:52
    .= Ga*(1,i)`1 by A4,A5,A11,JORDAN1A:73;
  then
A29: Gik <> LS.len LS by A1,A2,A17,A23,A28,JORDAN1G:7;
  then reconsider co as being_S-Seq FinSequence of TOP-REAL 2 by A9,JORDAN3:34;
A30: [len Ga,k] in Indices Ga by A14,A15,A21,MATRIX_0:30;
A31: LS.1 = LS/.1 by A27,PARTFUN1:def 6
    .= Emax by JORDAN1F:6;
  Emax`1 = Ebo by EUCLID:52
    .= Ga*(len Ga,k)`1 by A3,A14,JORDAN1A:71;
  then
A32: Gik <> LS.1 by A3,A17,A30,A31,JORDAN1G:7;
A33: len go >= 1+1 by TOPREAL1:def 8;
A34: Gij in rng US by A1,A4,A5,A10,A11,A13,JORDAN1G:4,JORDAN1J:40;
  then
A35: go is_sequence_on Ga by JORDAN1G:4,JORDAN1J:38;
A36: len co >= 1+1 by TOPREAL1:def 8;
A37: Gik in rng LS by A4,A5,A9,A11,A14,A15,JORDAN1G:5,JORDAN1J:40;
  then
A38: co is_sequence_on Ga by JORDAN1G:5,JORDAN1J:39;
  reconsider go as non constant s.c.c. being_S-Seq FinSequence of TOP-REAL 2
  by A33,A35,JGRAPH_1:12,JORDAN8:5;
  reconsider co as non constant s.c.c. being_S-Seq FinSequence of TOP-REAL 2
  by A36,A38,JGRAPH_1:12,JORDAN8:5;
A39: len go > 1 by A33,NAT_1:13;
  then
A40: len go in dom go by FINSEQ_3:25;
  then
A41: go/.len go = go.len go by PARTFUN1:def 6
    .= Gij by A10,JORDAN3:24;
  len co >= 1 by A36,XXREAL_0:2;
  then 1 in dom co by FINSEQ_3:25;
  then
A42: co/.1 = co.1 by PARTFUN1:def 6
    .= Gik by A9,JORDAN3:23;
  reconsider m = len go - 1 as Nat by A40,FINSEQ_3:26;
A43: m+1 = len go;
  then
A44: len go-'1 = m by NAT_D:34;
A45: LSeg(go,m) c= L~go by TOPREAL3:19;
A46: L~go c= L~US by A10,JORDAN3:41;
  then LSeg(go,m) c= L~US by A45;
  then
A47: LSeg(go,m) /\ LSeg(Gik,Gij) c= {Gij} by A6,XBOOLE_1:26;
  m >= 1 by A33,XREAL_1:19;
  then
A48: LSeg(go,m) = LSeg(go/.m,Gij) by A41,A43,TOPREAL1:def 3;
  {Gij} c= LSeg(go,m) /\ LSeg(Gik,Gij)
  proof
    let x be object;
A49: Gij in LSeg(Gik,Gij) by RLTOPSP1:68;
    assume x in {Gij};
    then
A50: x = Gij by TARSKI:def 1;
    Gij in LSeg(go,m) by A48,RLTOPSP1:68;
    hence thesis by A50,A49,XBOOLE_0:def 4;
  end;
  then
A51: LSeg(go,m) /\ LSeg(Gik,Gij) = {Gij} by A47;
A52: LSeg(co,1) c= L~co by TOPREAL3:19;
A53: L~co c= L~LS by A9,JORDAN3:42;
  then LSeg(co,1) c= L~LS by A52;
  then
A54: LSeg(co,1) /\ LSeg(Gik,Gij) c= {Gik} by A7,XBOOLE_1:26;
A55: LSeg(co,1) = LSeg(Gik,co/.(1+1)) by A36,A42,TOPREAL1:def 3;
  {Gik} c= LSeg(co,1) /\ LSeg(Gik,Gij)
  proof
    let x be object;
A56: Gik in LSeg(Gik,Gij) by RLTOPSP1:68;
    assume x in {Gik};
    then
A57: x = Gik by TARSKI:def 1;
    Gik in LSeg(co,1) by A55,RLTOPSP1:68;
    hence thesis by A57,A56,XBOOLE_0:def 4;
  end;
  then
A58: LSeg(Gik,Gij) /\ LSeg(co,1) = {Gik} by A54;
A59: go/.1 = US/.1 by A10,SPRECT_3:22
    .= Wmin by JORDAN1F:5;
  then
A60: go/.1 = LS/.len LS by JORDAN1F:8
    .= co/.len co by A9,JORDAN1J:35;
A61: rng go c= L~go by A33,SPPOL_2:18;
A62: rng co c= L~co by A36,SPPOL_2:18;
A63: {go/.1} c= L~go /\ L~co
  proof
    let x be object;
    assume x in {go/.1};
    then
A64: x = go/.1 by TARSKI:def 1;
    then
A65: x in rng go by FINSEQ_6:42;
    x in rng co by A60,A64,FINSEQ_6:168;
    hence thesis by A61,A62,A65,XBOOLE_0:def 4;
  end;
A66: LS.1 = LS/.1 by A27,PARTFUN1:def 6
    .= Emax by JORDAN1F:6;
A67: [len Ga,j] in Indices Ga by A1,A13,A21,MATRIX_0:30;
  L~go /\ L~co c= {go/.1}
  proof
    let x be object;
    assume
A68: x in L~go /\ L~co;
    then
A69: x in L~co by XBOOLE_0:def 4;
A70: now
      assume x = Emax;
      then
A71:  Emax = Gik by A9,A66,A69,JORDAN1E:7;
      Ga*(len Ga,j)`1 = Ebo by A1,A11,A13,JORDAN1A:71;
      then Emax`1 <> Ebo by A3,A17,A67,A71,JORDAN1G:7;
      hence contradiction by EUCLID:52;
    end;
    x in L~go by A68,XBOOLE_0:def 4;
    then x in L~US /\ L~LS by A46,A53,A69,XBOOLE_0:def 4;
    then x in {Wmin,Emax} by JORDAN1E:16;
    then x = Wmin or x = Emax by TARSKI:def 2;
    hence thesis by A59,A70,TARSKI:def 1;
  end;
  then
A72: L~go /\ L~co = {go/.1} by A63;
  set W2 = go/.2;
A73: 2 in dom go by A33,FINSEQ_3:25;
A74: now
    assume Gij`1 = Wbo;
    then Ga*(1,k)`1 = Ga*(j,i)`1 by A3,A14,JORDAN1A:73;
    hence contradiction by A1,A16,A22,JORDAN1G:7;
  end;
  go = mid(US,1,Gij..US) by A34,JORDAN1G:49
    .= US|(Gij..US) by A34,FINSEQ_4:21,FINSEQ_6:116;
  then
A75: W2 = US/.2 by A73,FINSEQ_4:70;
A76: Wmin in rng go by A59,FINSEQ_6:42;
  set pion = <*Gij,Gik*>;
A77: now
    let n be Nat;
    assume n in dom pion;
    then n in {1,2} by FINSEQ_1:2,89;
    then n = 1 or n = 2 by TARSKI:def 2;
    hence ex j,i be Nat st [j,i] in Indices Ga & pion/.n = Ga*(j,i)
    by A16,A17,FINSEQ_4:17;
  end;
A78: Gik <> Gij by A12,A16,A17,GOBOARD1:5;
  Gik`2 = Ga*(1,i)`2 by A3,A4,A5,A14,GOBOARD5:1
    .= Gij`2 by A1,A4,A5,A11,A13,GOBOARD5:1;
  then LSeg(Gik,Gij) is horizontal by SPPOL_1:15;
  then pion is being_S-Seq by A78,JORDAN1B:8;
  then consider pion1 be FinSequence of TOP-REAL 2 such that
A79: pion1 is_sequence_on Ga and
A80: pion1 is being_S-Seq and
A81: L~pion = L~pion1 and
A82: pion/.1 = pion1/.1 and
A83: pion/.len pion = pion1/.len pion1 and
A84: len pion <= len pion1 by A77,GOBOARD3:2;
  reconsider pion1 as being_S-Seq FinSequence of TOP-REAL 2 by A80;
  set godo = go^'pion1^'co;
A85: 1+1 <= len Cage(C,n) by GOBOARD7:34,XXREAL_0:2;
A86: 1+1 <= len Rotate(Cage(C,n),Wmin) by GOBOARD7:34,XXREAL_0:2;
  len (go^'pion1) >= len go by TOPREAL8:7;
  then
A87: len (go^'pion1) >= 1+1 by A33,XXREAL_0:2;
  then
A88: len (go^'pion1) > 1+0 by NAT_1:13;
A89: len godo >= len (go^'pion1) by TOPREAL8:7;
  then
A90: 1+1 <= len godo by A87,XXREAL_0:2;
A91: US is_sequence_on Ga by JORDAN1G:4;
A92: go/.len go = pion1/.1 by A41,A82,FINSEQ_4:17;
  then
A93: go^'pion1 is_sequence_on Ga by A35,A79,TOPREAL8:12;
A94: (go^'pion1)/.len (go^'pion1) = pion/.len pion by A83,FINSEQ_6:156
    .= pion/.2 by FINSEQ_1:44
    .= co/.1 by A42,FINSEQ_4:17;
  then
A95: godo is_sequence_on Ga by A38,A93,TOPREAL8:12;
  LSeg(pion1,1) c= L~<*Gij,Gik*> by A81,TOPREAL3:19;
  then LSeg(pion1,1) c= LSeg(Gij,Gik) by SPPOL_2:21;
  then
A96: LSeg(go,len go-'1) /\ LSeg(pion1,1) c= {Gij} by A44,A51,XBOOLE_1:27;
A97: len pion1 >= 1+1 by A84,FINSEQ_1:44;
  {Gij} c= LSeg(go,m) /\ LSeg(pion1,1)
  proof
    let x be object;
    assume x in {Gij};
    then
A98: x = Gij by TARSKI:def 1;
A99: Gij in LSeg(go,m) by A48,RLTOPSP1:68;
    Gij in LSeg(pion1,1) by A41,A92,A97,TOPREAL1:21;
    hence thesis by A98,A99,XBOOLE_0:def 4;
  end;
  then LSeg(go,len go-'1) /\ LSeg(pion1,1) = { go/.len go } by A41,A44,A96;
  then
A100: go^'pion1 is unfolded by A92,TOPREAL8:34;
  len pion1 >= 2+0 by A84,FINSEQ_1:44;
  then
A101: len pion1-2 >= 0 by XREAL_1:19;
  len (go^'pion1)+1-1 = len go+len pion1-1 by FINSEQ_6:139;
  then len (go^'pion1)-1 = len go + (len pion1-2)
    .= len go + (len pion1-'2) by A101,XREAL_0:def 2;
  then
A102: len (go^'pion1)-'1 = len go + (len pion1-'2) by XREAL_0:def 2;
A103: len pion1-1 >= 1 by A97,XREAL_1:19;
  then
A104: len pion1-'1 = len pion1-1 by XREAL_0:def 2;
A105: len pion1-'2+1 = len pion1-2+1 by A101,XREAL_0:def 2
    .= len pion1-'1 by A103,XREAL_0:def 2;
  len pion1-1+1 <= len pion1;
  then
A106: len pion1-'1 < len pion1 by A104,NAT_1:13;
  LSeg(pion1,len pion1-'1) c= L~<*Gij,Gik*> by A81,TOPREAL3:19;
  then LSeg(pion1,len pion1-'1) c= LSeg(Gij,Gik) by SPPOL_2:21;
  then
A107: LSeg(pion1,len pion1-'1) /\ LSeg(co,1) c= {Gik} by A58,XBOOLE_1:27;
  {Gik} c= LSeg(pion1,len pion1-'1) /\ LSeg(co,1)
  proof
    let x be object;
    assume x in {Gik};
    then
A108: x = Gik by TARSKI:def 1;
    pion1/.(len pion1-'1+1) = pion/.2 by A83,A104,FINSEQ_1:44
      .= Gik by FINSEQ_4:17;
    then
A109: Gik in LSeg(pion1,len pion1-'1) by A103,A104,TOPREAL1:21;
    Gik in LSeg(co,1) by A55,RLTOPSP1:68;
    hence thesis by A108,A109,XBOOLE_0:def 4;
  end;
  then LSeg(pion1,len pion1-'1) /\ LSeg(co,1) = {Gik} by A107;
  then
A110: LSeg(go^'pion1,len go+(len pion1-'2)) /\ LSeg(co,1) = {(go^'pion1)/.
  len (go^'pion1)} by A42,A92,A94,A105,A106,TOPREAL8:31;
A111: (go^'pion1) is non trivial by A87,NAT_D:60;
A112: rng pion1 c= L~pion1 by A97,SPPOL_2:18;
A113: {pion1/.1} c= L~go /\ L~pion1
  proof
    let x be object;
    assume x in {pion1/.1};
    then
A114: x = pion1/.1 by TARSKI:def 1;
    then
A115: x in rng pion1 by FINSEQ_6:42;
    x in rng go by A92,A114,FINSEQ_6:168;
    hence thesis by A61,A112,A115,XBOOLE_0:def 4;
  end;
  L~go /\ L~pion1 c= {pion1/.1}
  proof
    let x be object;
    assume
A116: x in L~go /\ L~pion1;
    then
A117: x in L~pion1 by XBOOLE_0:def 4;
    x in L~go by A116,XBOOLE_0:def 4;
    then x in L~pion1 /\ L~US by A46,A117,XBOOLE_0:def 4;
    hence thesis by A6,A41,A81,A92,SPPOL_2:21;
  end;
  then
A118: L~go /\ L~pion1 = {pion1/.1} by A113;
  then
A119: (go^'pion1) is s.n.c. by A92,JORDAN1J:54;
  rng go /\ rng pion1 c= {pion1/.1} by A61,A112,A118,XBOOLE_1:27;
  then
A120: go^'pion1 is one-to-one by JORDAN1J:55;
A121: pion/.len pion = pion/.2 by FINSEQ_1:44
    .= co/.1 by A42,FINSEQ_4:17;
A122: {pion1/.len pion1} c= L~co /\ L~pion1
  proof
    let x be object;
    assume x in {pion1/.len pion1};
    then
A123: x = pion1/.len pion1 by TARSKI:def 1;
    then
A124: x in rng pion1 by FINSEQ_6:168;
    x in rng co by A83,A121,A123,FINSEQ_6:42;
    hence thesis by A62,A112,A124,XBOOLE_0:def 4;
  end;
  L~co /\ L~pion1 c= {pion1/.len pion1}
  proof
    let x be object;
    assume
A125: x in L~co /\ L~pion1;
    then
A126: x in L~pion1 by XBOOLE_0:def 4;
    x in L~co by A125,XBOOLE_0:def 4;
    then x in L~pion1 /\ L~LS by A53,A126,XBOOLE_0:def 4;
    hence thesis by A7,A42,A81,A83,A121,SPPOL_2:21;
  end;
  then
A127: L~co /\ L~pion1 = {pion1/.len pion1} by A122;
A128: L~(go^'pion1) /\ L~co = (L~go \/ L~pion1) /\ L~co by A92,TOPREAL8:35
    .= {go/.1} \/ {co/.1} by A72,A83,A121,A127,XBOOLE_1:23
    .= {(go^'pion1)/.1} \/ {co/.1} by FINSEQ_6:155
    .= {(go^'pion1)/.1,co/.1} by ENUMSET1:1;
  co/.len co = (go^'pion1)/.1 by A60,FINSEQ_6:155;
  then reconsider
  godo as non constant standard special_circular_sequence by A90,A94,A95,A100
,A102,A110,A111,A119,A120,A128,JORDAN8:4,5,TOPREAL8:11,33,34;
A129: LA is_an_arc_of E-max C,W-min C by JORDAN6:def 9;
  then
A130: LA is connected by JORDAN6:10;
A131: W-min C in LA by A129,TOPREAL1:1;
A132: E-max C in LA by A129,TOPREAL1:1;
  set ff = Rotate(Cage(C,n),Wmin);
  Wmin in rng Cage(C,n) by SPRECT_2:43;
  then
A133: ff/.1 = Wmin by FINSEQ_6:92;
A134: L~ff = L~Cage(C,n) by REVROT_1:33;
  then (W-max L~ff)..ff > 1 by A133,SPRECT_5:22;
  then (N-min L~ff)..ff > 1 by A133,A134,SPRECT_5:23,XXREAL_0:2;
  then (N-max L~ff)..ff > 1 by A133,A134,SPRECT_5:24,XXREAL_0:2;
  then
A135: Emax..ff > 1 by A133,A134,SPRECT_5:25,XXREAL_0:2;
A136: now
    assume
A137: Gij..US <= 1;
    Gij..US >= 1 by A34,FINSEQ_4:21;
    then Gij..US = 1 by A137,XXREAL_0:1;
    then Gij = US/.1 by A34,FINSEQ_5:38;
    hence contradiction by A19,A24,JORDAN1F:5;
  end;
A138: Cage(C,n) is_sequence_on Ga by JORDAN9:def 1;
  then
A139: ff is_sequence_on Ga by REVROT_1:34;
A140: right_cell(godo,1,Ga)\L~godo c= RightComp godo by A90,A95,JORDAN9:27;
A141: L~godo = L~(go^'pion1) \/ L~co by A94,TOPREAL8:35
    .= L~go \/ L~pion1 \/ L~co by A92,TOPREAL8:35;
A142: L~Cage(C,n) = L~US \/ L~LS by JORDAN1E:13;
  then
A143: L~US c= L~Cage(C,n) by XBOOLE_1:7;
A144: L~LS c= L~Cage(C,n) by A142,XBOOLE_1:7;
A145: L~go c= L~Cage(C,n) by A46,A143;
A146: L~co c= L~Cage(C,n) by A53,A144;
A147: W-min C in C by SPRECT_1:13;
A148: L~pion = LSeg(Gik,Gij) by SPPOL_2:21;
A149: now
    assume W-min C in L~godo;
    then
A150: W-min C in L~go \/ L~pion1 or W-min C in L~co by A141,XBOOLE_0:def 3;
    per cases by A150,XBOOLE_0:def 3;
    suppose
      W-min C in L~go;
      then C meets L~Cage(C,n) by A145,A147,XBOOLE_0:3;
      hence contradiction by JORDAN10:5;
    end;
    suppose
      W-min C in L~pion1;
      hence contradiction by A8,A81,A131,A148,XBOOLE_0:3;
    end;
    suppose
      W-min C in L~co;
      then C meets L~Cage(C,n) by A146,A147,XBOOLE_0:3;
      hence contradiction by JORDAN10:5;
    end;
  end;
  right_cell(Rotate(Cage(C,n),Wmin),1) = right_cell(ff,1,GoB ff) by A86,
JORDAN1H:23
    .= right_cell(ff,1,GoB Cage(C,n)) by REVROT_1:28
    .= right_cell(ff,1,Ga) by JORDAN1H:44
    .= right_cell(ff-:Emax,1,Ga) by A135,A139,JORDAN1J:53
    .= right_cell(US,1,Ga) by JORDAN1E:def 1
    .= right_cell(R_Cut(US,Gij),1,Ga) by A34,A91,A136,JORDAN1J:52
    .= right_cell(go^'pion1,1,Ga) by A39,A93,JORDAN1J:51
    .= right_cell(godo,1,Ga) by A88,A95,JORDAN1J:51;
  then W-min C in right_cell(godo,1,Ga) by JORDAN1I:6;
  then
A151: W-min C in right_cell(godo,1,Ga)\L~godo by A149,XBOOLE_0:def 5;
A152: godo/.1 = (go^'pion1)/.1 by FINSEQ_6:155
    .= Wmin by A59,FINSEQ_6:155;
A153: len US >= 2 by A18,XXREAL_0:2;
A154: godo/.2 = (go^'pion1)/.2 by A87,FINSEQ_6:159
    .= US/.2 by A33,A75,FINSEQ_6:159
    .= (US^'LS)/.2 by A153,FINSEQ_6:159
    .= Rotate(Cage(C,n),Wmin)/.2 by JORDAN1E:11;
A155: L~go \/ L~co is compact by COMPTS_1:10;
  Wmin in L~go \/ L~co by A61,A76,XBOOLE_0:def 3;
  then
A156: W-min (L~go \/ L~co) = Wmin by A145,A146,A155,JORDAN1J:21,XBOOLE_1:8;
A157: (W-min (L~go \/ L~co))`1 = W-bound (L~go \/ L~co) by EUCLID:52;
A158: Wmin`1 = Wbo by EUCLID:52;
A159: Gij`1 <= Gik`1 by A1,A2,A3,A4,A5,SPRECT_3:13;
  then W-bound LSeg(Gik,Gij) = Gij`1 by SPRECT_1:54;
  then
A160: W-bound L~pion1 = Gij`1 by A81,SPPOL_2:21;
  Gij`1 >= Wbo by A10,A143,PSCOMP_1:24;
  then Gij`1 > Wbo by A74,XXREAL_0:1;
  then W-min (L~go\/L~co\/L~pion1) = W-min (L~go \/ L~co) by A155,A156,A157
,A158,A160,JORDAN1J:33;
  then
A161: W-min L~godo = Wmin by A141,A156,XBOOLE_1:4;
A162: rng godo c= L~godo by A87,A89,SPPOL_2:18,XXREAL_0:2;
  2 in dom godo by A90,FINSEQ_3:25;
  then
A163: godo/.2 in rng godo by PARTFUN2:2;
  godo/.2 in W-most L~Cage(C,n) by A154,JORDAN1I:25;
  then (godo/.2)`1 = (W-min L~godo)`1 by A161,PSCOMP_1:31
    .= W-bound L~godo by EUCLID:52;
  then godo/.2 in W-most L~godo by A162,A163,SPRECT_2:12;
  then Rotate(godo,W-min L~godo)/.2 in W-most L~godo by A152,A161,FINSEQ_6:89;
  then reconsider godo as clockwise_oriented non constant standard
  special_circular_sequence by JORDAN1I:25;
  len US in dom US by FINSEQ_5:6;
  then
A164: US.len US = US/.len US by PARTFUN1:def 6
    .= Emax by JORDAN1F:7;
A165: east_halfline E-max C misses L~go
  proof
    assume east_halfline E-max C meets L~go;
    then consider p be object such that
A166: p in east_halfline E-max C and
A167: p in L~go by XBOOLE_0:3;
    reconsider p as Point of TOP-REAL 2 by A166;
    p in L~US by A46,A167;
    then p in east_halfline E-max C /\ L~Cage(C,n) by A143,A166,XBOOLE_0:def 4;
    then
A168: p`1 = Ebo by JORDAN1A:83,PSCOMP_1:50;
    then
A169: p = Emax by A46,A167,JORDAN1J:46;
    then Emax = Gij by A10,A164,A167,JORDAN1J:43;
    then Gij`1 = Ga*(len Ga,k)`1 by A3,A14,A168,A169,JORDAN1A:71;
    hence contradiction by A2,A3,A16,A30,JORDAN1G:7;
  end;
  now
    assume east_halfline E-max C meets L~godo;
    then
A170: east_halfline E-max C meets (L~go \/ L~pion1) or east_halfline E-max
    C meets L~co by A141,XBOOLE_1:70;
    per cases by A170,XBOOLE_1:70;
    suppose
      east_halfline E-max C meets L~go;
      hence contradiction by A165;
    end;
    suppose
      east_halfline E-max C meets L~pion1;
      then consider p be object such that
A171: p in east_halfline E-max C and
A172: p in L~pion1 by XBOOLE_0:3;
      reconsider p as Point of TOP-REAL 2 by A171;
A173: p`2 = (E-max C)`2 by A171,TOPREAL1:def 11;
      k+1 <= len Ga by A3,NAT_1:13;
      then k+1-1 <= len Ga-1 by XREAL_1:9;
      then
A174: k <= len Ga-'1 by XREAL_0:def 2;
      len Ga-'1 <= len Ga by NAT_D:35;
      then
A175: Gik`1 <= Ga*(len Ga-'1,1)`1 by A4,A5,A11,A14,A21,A174,JORDAN1A:18;
      p`1 <= Gik`1 by A81,A148,A159,A172,TOPREAL1:3;
      then p`1 <= Ga*(len Ga-'1,1)`1 by A175,XXREAL_0:2;
      then p`1 <= E-bound C by A21,JORDAN8:12;
      then
A176: p`1 <= (E-max C)`1 by EUCLID:52;
      p`1 >= (E-max C)`1 by A171,TOPREAL1:def 11;
      then p`1 = (E-max C)`1 by A176,XXREAL_0:1;
      then p = E-max C by A173,TOPREAL3:6;
      hence contradiction by A8,A81,A132,A148,A172,XBOOLE_0:3;
    end;
    suppose
      east_halfline E-max C meets L~co;
      then consider p be object such that
A177: p in east_halfline E-max C and
A178: p in L~co by XBOOLE_0:3;
      reconsider p as Point of TOP-REAL 2 by A177;
A179: p in LSeg(co,Index(p,co)) by A178,JORDAN3:9;
      consider t be Nat such that
A180: t in dom LS and
A181: LS.t = Gik by A37,FINSEQ_2:10;
      1 <= t by A180,FINSEQ_3:25;
      then
A182: 1 < t by A32,A181,XXREAL_0:1;
      t <= len LS by A180,FINSEQ_3:25;
      then Index(Gik,LS)+1 = t by A181,A182,JORDAN3:12;
      then
A183: len L_Cut(LS,Gik) = len LS-Index(Gik,LS) by A9,A181,JORDAN3:26;
      Index(p,co) < len co by A178,JORDAN3:8;
      then Index(p,co) < len LS-'Index(Gik,LS) by A183,XREAL_0:def 2;
      then Index(p,co)+1 <= len LS-'Index(Gik,LS) by NAT_1:13;
      then
A184: Index(p,co) <= len LS-'Index(Gik,LS)-1 by XREAL_1:19;
A185: co = mid(LS,Gik..LS,len LS) by A37,JORDAN1J:37;
      p in L~LS by A53,A178;
      then p in east_halfline E-max C /\ L~Cage(C,n) by A144,A177,
XBOOLE_0:def 4;
      then
A186: p`1 = Ebo by JORDAN1A:83,PSCOMP_1:50;
A187: Index(Gik,LS)+1 = Gik..LS by A32,A37,JORDAN1J:56;
      0+Index(Gik,LS) < len LS by A9,JORDAN3:8;
      then len LS-Index(Gik,LS) > 0 by XREAL_1:20;
      then Index(p,co) <= len LS-Index(Gik,LS)-1 by A184,XREAL_0:def 2;
      then Index(p,co) <= len LS-Gik..LS by A187;
      then Index(p,co) <= len LS-'Gik..LS by XREAL_0:def 2;
      then
A188: Index(p,co) < len LS-'(Gik..LS)+1 by NAT_1:13;
A189: 1<=Index(p,co) by A178,JORDAN3:8;
A190: Gik..LS<=len LS by A37,FINSEQ_4:21;
      Gik..LS <> len LS by A29,A37,FINSEQ_4:19;
      then
A191: Gik..LS < len LS by A190,XXREAL_0:1;
A192: 1+1 <= len LS by A25,XXREAL_0:2;
      then
A193: 2 in dom LS by FINSEQ_3:25;
      set tt = Index(p,co)+(Gik..LS)-'1;
      set RC = Rotate(Cage(C,n),Emax);
A194: E-max C in right_cell(RC,1) by JORDAN1I:7;
A195: GoB RC = GoB Cage(C,n) by REVROT_1:28
        .= Ga by JORDAN1H:44;
A196: L~RC = L~Cage(C,n) by REVROT_1:33;
      consider g2 be Nat such that
A197: 1 <= g2 and
A198: g2 <= width Ga and
A199: Emax = Ga*(len Ga,g2) by JORDAN1D:25;
A200: len Ga >= 4 by JORDAN8:10;
      then len Ga >= 1 by XXREAL_0:2;
      then
A201: [len Ga,g2] in Indices Ga by A197,A198,MATRIX_0:30;
A202: len RC = len Cage(C,n) by FINSEQ_6:179;
      LS = RC-:Wmin by JORDAN1G:18;
      then
A203: LSeg(LS,1) = LSeg(RC,1) by A192,SPPOL_2:9;
A204: Emax in rng Cage(C,n) by SPRECT_2:46;
      RC is_sequence_on Ga by A138,REVROT_1:34;
      then consider ii,g be Nat such that
A205: [ii,g+1] in Indices Ga and
A206: [ii,g] in Indices Ga and
A207: RC/.1 = Ga*(ii,g+1) and
A208: RC/.(1+1) = Ga*(ii,g) by A85,A196,A202,A204,FINSEQ_6:92,JORDAN1I:23;
A209: g+1+1 <> g;
A210: 1 <= g by A206,MATRIX_0:32;
      RC/.1 = E-max L~RC by A196,A204,FINSEQ_6:92;
      then
A211: ii = len Ga by A196,A205,A207,A199,A201,GOBOARD1:5;
      then ii-1 >= 4-1 by A200,XREAL_1:9;
      then
A212: ii-1 >= 1 by XXREAL_0:2;
      then
A213: 1 <= ii-'1 by XREAL_0:def 2;
A214: g <= width Ga by A206,MATRIX_0:32;
      then
A215: Ga*(len Ga,g)`1 = Ebo by A11,A210,JORDAN1A:71;
A216: g+1 <= width Ga by A205,MATRIX_0:32;
      ii+1 <> ii;
      then
A217: right_cell(RC,1) = cell(Ga,ii-'1,g) by A85,A202,A195,A205,A206,A207,A208
,A209,GOBOARD5:def 6;
A218: ii <= len Ga by A206,MATRIX_0:32;
A219: 1 <= ii by A206,MATRIX_0:32;
A220: ii <= len Ga by A205,MATRIX_0:32;
A221: 1 <= g+1 by A205,MATRIX_0:32;
      then
A222: Ebo = Ga*(len Ga,g+1)`1 by A11,A216,JORDAN1A:71;
A223: 1 <= ii by A205,MATRIX_0:32;
      then
A224: ii-'1+1 = ii by XREAL_1:235;
      then
A225: ii-'1 < len Ga by A220,NAT_1:13;
      then
A226: Ga*(ii-'1,g+1)`2 = Ga*(1,g+1)`2 by A221,A216,A213,GOBOARD5:1
        .= Ga*(ii,g+1)`2 by A223,A220,A221,A216,GOBOARD5:1;
A227: (E-max C)`2 = p`2 by A177,TOPREAL1:def 11;
      then
A228: p`2 <= Ga*(ii-'1,g+1)`2 by A194,A220,A216,A210,A217,A224,A212,JORDAN9:17;
A229: Ga*(ii-'1,g)`2 = Ga*(1,g)`2 by A210,A214,A213,A225,GOBOARD5:1
        .= Ga*(ii,g)`2 by A219,A218,A210,A214,GOBOARD5:1;
      Ga*(ii-'1,g)`2 <= p`2 by A227,A194,A220,A216,A210,A217,A224,A212,
JORDAN9:17;
      then p in LSeg(RC/.1,RC/.(1+1)) by A186,A207,A208,A211,A228,A229,A226
,A215,A222,GOBOARD7:7;
      then
A230: p in LSeg(LS,1) by A85,A203,A202,TOPREAL1:def 3;
      1<=Gik..LS by A37,FINSEQ_4:21;
      then
A231: LSeg(mid(LS,Gik..LS,len LS),Index(p,co)) = LSeg(LS,Index(p,co)+(
      Gik..LS)-'1) by A191,A189,A188,JORDAN4:19;
      1<=Index(Gik,LS) by A9,JORDAN3:8;
      then
A232: 1+1 <= Gik..LS by A187,XREAL_1:7;
      then Index(p,co)+Gik..LS >= 1+1+1 by A189,XREAL_1:7;
      then Index(p,co)+Gik..LS-1 >= 1+1+1-1 by XREAL_1:9;
      then
A233: tt >= 1+1 by XREAL_0:def 2;
      now
        per cases by A233,XXREAL_0:1;
        suppose
          tt > 1+1;
          then LSeg(LS,1) misses LSeg(LS,tt) by TOPREAL1:def 7;
          hence contradiction by A230,A179,A185,A231,XBOOLE_0:3;
        end;
        suppose
A234:     tt = 1+1;
          then 1+1 = Index(p,co)+(Gik..LS)-1 by XREAL_0:def 2;
          then 1+1+1 = Index(p,co)+(Gik..LS);
          then
A235:     Gik..LS = 2 by A189,A232,JORDAN1E:6;
          LSeg(LS,1) /\ LSeg(LS,tt) = {LS/.2} by A25,A234,TOPREAL1:def 6;
          then p in {LS/.2} by A230,A179,A185,A231,XBOOLE_0:def 4;
          then
A236:     p = LS/.2 by TARSKI:def 1;
          then
A237:     p in rng LS by A193,PARTFUN2:2;
          p..LS = 2 by A193,A236,FINSEQ_5:41;
          then p = Gik by A37,A235,A237,FINSEQ_5:9;
          then Gik`1 = Ebo by A236,JORDAN1G:32;
          then Gik`1 = Ga*(len Ga,j)`1 by A1,A11,A13,JORDAN1A:71;
          hence contradiction by A3,A17,A67,JORDAN1G:7;
        end;
      end;
      hence contradiction;
    end;
  end;
  then east_halfline E-max C c= (L~godo)` by SUBSET_1:23;
  then consider W be Subset of TOP-REAL 2 such that
A238: W is_a_component_of (L~godo)` and
A239: east_halfline E-max C c= W by GOBOARD9:3;
  W is not bounded by A239,JORDAN2C:121,RLTOPSP1:42;
  then W is_outside_component_of L~godo by A238,JORDAN2C:def 3;
  then W c= UBD L~godo by JORDAN2C:23;
  then
A240: east_halfline E-max C c= UBD L~godo by A239;
  E-max C in east_halfline E-max C by TOPREAL1:38;
  then E-max C in UBD L~godo by A240;
  then E-max C in LeftComp godo by GOBRD14:36;
  then LA meets L~godo by A130,A131,A132,A140,A151,JORDAN1J:36;
  then
A241: LA meets (L~go \/ L~pion1) or LA meets L~co by A141,XBOOLE_1:70;
A242: LA c= C by JORDAN6:61;
  per cases by A241,XBOOLE_1:70;
  suppose
    LA meets L~go;
    then LA meets L~Cage(C,n) by A46,A143,XBOOLE_1:1,63;
    hence contradiction by A242,JORDAN10:5,XBOOLE_1:63;
  end;
  suppose
    LA meets L~pion1;
    hence contradiction by A8,A81,A148;
  end;
  suppose
    LA meets L~co;
    then LA meets L~Cage(C,n) by A53,A144,XBOOLE_1:1,63;
    hence contradiction by A242,JORDAN10:5,XBOOLE_1:63;
  end;
end;
