reserve C for Simple_closed_curve,
  i for Nat;
reserve R for non empty Subset of TOP-REAL 2,
  j, k, m, n for Nat;

theorem Th36:
  South_Arc C c= C
proof
  let x be object;
  assume
A1: x in South_Arc C;
  assume
A2: not x in C;
  reconsider x as Point of TOP-REAL 2 by A1;
A3: x in C` by A2,SUBSET_1:29;
  reconsider e = x as Point of Euclid 2 by EUCLID:67;
A4: South_Arc C = Lim_inf Lower_Appr C by JORDAN19:def 4;
A5: (BDD C) \/ (UBD C) = C` by JORDAN2C:27;
  per cases by A3,A5,XBOOLE_0:def 3;
  suppose
A6: x in BDD C;
    reconsider OO = BDD C as Subset of TopSpaceMetr Euclid 2 by Lm4;
    OO is open by Lm4,PRE_TOPC:30;
    then consider r being Real such that
A7: r > 0 and
A8: Ball(e,r) c= BDD C by A6,TOPMETR:15;
    consider k being Nat such that
A9: for m being Nat st m > k holds (Lower_Appr C).m meets
    Ball(e,r) by A1,A4,A7,KURATO_2:14;
A10: Lower_Arc L~Cage(C,k+1) c= L~Cage(C,k+1) by JORDAN6:61;
A11: (Lower_Appr C).(k+1) = Lower_Arc L~Cage(C,k+1) by JORDAN19:def 2;
A12: k+0 < k+1 by XREAL_1:8;
    Ball(e,r) misses L~Cage(C,k+1) by A8,JORDAN10:19,XBOOLE_1:63;
    hence thesis by A9,A12,A11,A10,XBOOLE_1:63;
  end;
  suppose
A13: x in UBD C;
    union UBD-Family C = UBD C by JORDAN10:14;
    then consider A being set such that
A14: x in A and
A15: A in UBD-Family C by A13,TARSKI:def 4;
    UBD-Family C = the set of all UBD L~Cage(C,m) where m is Nat
 by JORDAN10:def 1;
    then consider m being Nat such that
A16: A = UBD L~Cage(C,m) by A15;
    reconsider OO = LeftComp Cage(C,m) as Subset of TopSpaceMetr Euclid 2 by
Lm4;
A17: OO is open by Lm4,PRE_TOPC:30;
    x in LeftComp Cage(C,m) by A14,A16,GOBRD14:36;
    then consider r being Real such that
A18: r > 0 and
A19: Ball(e,r) c= LeftComp Cage(C,m) by A17,TOPMETR:15;
    consider k being Nat such that
A20: for m being Nat st m > k holds (Lower_Appr C).m meets
    Ball(e,r) by A1,A4,A18,KURATO_2:14;
    thus thesis
    proof
      per cases;
      suppose
A21:    m > k;
A22:    (Lower_Appr C).m = Lower_Arc L~Cage(C,m) by JORDAN19:def 2;
A23:    Lower_Arc L~Cage(C,m) c= L~Cage(C,m) by JORDAN6:61;
        Ball(e,r) misses L~Cage(C,m) by A19,SPRECT_3:26,XBOOLE_1:63;
        hence thesis by A20,A21,A22,A23,XBOOLE_1:63;
      end;
      suppose
        m <= k;
        then LeftComp Cage(C,m) c= LeftComp Cage(C,k) by JORDAN1H:47;
        then
A24:    Ball(e,r) c= LeftComp Cage(C,k) by A19;
A25:    k+0 < k+1 by XREAL_1:8;
        then LeftComp Cage(C,k) c= LeftComp Cage(C,k+1) by JORDAN1H:47;
        then Ball(e,r) c= LeftComp Cage(C,k+1) by A24;
        then
A26:    Ball(e,r) misses L~Cage(C,k+1) by SPRECT_3:26,XBOOLE_1:63;
A27:    Lower_Arc L~Cage(C,k+1) c= L~Cage(C,k+1) by JORDAN6:61;
        (Lower_Appr C).(k+1) = Lower_Arc L~Cage(C,k+1) by JORDAN19:def 2;
        hence thesis by A20,A25,A26,A27,XBOOLE_1:63;
      end;
    end;
  end;
end;
