reserve x,y for object,
  N for Element of NAT,
  c,i,j,k,m,n for Nat,
  D for non empty set,
  s for Element of 2Set Seg (n+2),
  p for Element of Permutations(n) ,
  p1, q1 for Element of Permutations(n+1),
  p2 for Element of Permutations(n +2),
  K for Field,
  a for Element of K,
  f for FinSequence of K,
  A for (Matrix of K),
  AD for Matrix of n,m,D,
  pD for FinSequence of D,
  M for Matrix of n,K;

theorem
  for M be Matrix of n,K st M is invertible for i,j st [i,j] in Indices
  (M~) holds M~*(i,j) = (Det M)" * power(K).(-1_K,i+j) * Minor(M,j,i)
proof
  let M be Matrix of n,K;
  assume M is invertible;
  then
A1: Det M<>0.K by Th34;
  set D=Det M;
  set COF=Matrix_of_Cofactor M;
  let i,j;
  assume [i,j] in Indices (M~);
  then
A2: [i,j] in Indices (COF@) by MATRIX_0:26;
  then
A3: [j,i] in Indices COF by MATRIX_0:def 6;
  thus M~*(i,j)=(D" * COF@)*(i,j) by A1,Th35
    .=D"*((COF@)*(i,j)) by A2,MATRIX_3:def 5
    .=D"*(COF*(j,i)) by A3,MATRIX_0:def 6
    .=D"*Cofactor(M,j,i) by A3,Def6
    .=D"*power(K).(-1_K,i+j) * Minor(M,j,i) by GROUP_1:def 3;
end;
