
theorem Th37:
  for X,Y,Z be RealNormSpace,
      I be Lipschitzian LinearOperator of Y,Z
    st I is one-to-one onto isometric
  holds
  ex L be Lipschitzian LinearOperator of
    R_NormSpace_of_BoundedLinearOperators(X,Y),
    R_NormSpace_of_BoundedLinearOperators(X,Z)
  st L is one-to-one onto isometric
   & for f be Point of R_NormSpace_of_BoundedLinearOperators(X,Y)
     holds L.f = I * f
  proof
    let X,Y,Z be RealNormSpace,
        I be Lipschitzian LinearOperator of Y,Z;
    assume
    A1: I is one-to-one onto isometric;

    then
    consider J be LinearOperator of Z,Y
    such that
    A2: J = I" and
        J is one-to-one onto and
    A3: J is isometric by NDIFF_7:9;

    reconsider J as Lipschitzian LinearOperator of Z,Y by A3;

    set F = the carrier of R_NormSpace_of_BoundedLinearOperators(X,Y);
    set G = the carrier of R_NormSpace_of_BoundedLinearOperators(X,Z);
    defpred P1[Function,Function] means $2 = I * $1;

    A4: for f be Element of F
        ex g be Element of G st P1[f,g]
    proof
      let f be Element of F;
      reconsider f as Lipschitzian LinearOperator of X,Y
        by LOPBAN_1:def 9;
      I * f is Lipschitzian LinearOperator of X,Z by LOPBAN_2:2;
      then reconsider g = I * f as Element of G by LOPBAN_1:def 9;
      take g;
      thus thesis;
    end;

    consider L be Function of F,G such that
    A5: for f be Element of F holds P1[f, L.f] from FUNCT_2:sch 3(A4);

    A6: for f1, f2 be object
         st f1 in F & f2 in F & L.f1 = L.f2
        holds f1 = f2
    proof
      let f1, f2 be object;
      assume
      A7: f1 in F & f2 in F & L.f1 = L.f2; then
      reconsider u1 = f1, u2 = f2 as Point of
        R_NormSpace_of_BoundedLinearOperators(X,Y);
      reconsider v1 = u1, v2 = u2 as Lipschitzian LinearOperator of X,Y
        by LOPBAN_1:def 9;

      L.v1 = I * v1 by A5;
      then I * v1 = I * v2 by A5,A7;
      then J * (I * v1) = (J * I) * v2 by RELAT_1:36;
      then
      A8: J * I * v1 = J * I * v2 by RELAT_1:36;
      A9: J * I = id the carrier of Y by A1,A2,FUNCT_2:29;
      then J * I * v1 = v1 by FUNCT_2:17;
      hence thesis by A8,A9,FUNCT_2:17;
    end;

    A10: for g be object st g in G holds
         ex f be object st f in F & g = L.f
    proof
      let g be object;
      assume g in G;
      then reconsider g1 = g as Point of
        R_NormSpace_of_BoundedLinearOperators(X,Z);
      reconsider g2 = g1 as Lipschitzian LinearOperator of X,Z
        by LOPBAN_1:def 9;
      reconsider f1 = J * g2 as Lipschitzian LinearOperator of X,Y
        by LOPBAN_2:2;
      reconsider f = f1 as Point of
        R_NormSpace_of_BoundedLinearOperators(X,Y)
        by LOPBAN_1:def 9;

      take f;
      thus f in F;
      A11: I * J = id the carrier of Z by A1,A2,FUNCT_2:29;
      thus L.f
       = I * (J * g2) by A5
      .= (I * J) * g2 by RELAT_1:36
      .= g by A11,FUNCT_2:17;
    end;

    A12: for f1,f2 be Point of R_NormSpace_of_BoundedLinearOperators(X,Y)
         holds L.(f1 + f2) = L.f1 + L.f2
    proof
      let f1,f2 be Point of R_NormSpace_of_BoundedLinearOperators(X,Y);
      reconsider ff1 = f1, ff2 = f2, f12 = f1 + f2
        as Lipschitzian LinearOperator of X,Y
        by LOPBAN_1:def 9;

      A13: L.f1 = I * f1 by A5;
      A14: L.f2 = I * f2 by A5;
      A15: L.(f1 + f2) = I * (f1 + f2) by A5;
      set g1 = L.f1, g2 = L.f2, g12 = L.(f1 + f2);

      for x be VECTOR of X holds g12.x = g1.x + g2.x
      proof
        let x be VECTOR of X;
        A16: g1.x = I.(ff1.x) by A13,FUNCT_2:15;
        A17: g2.x = I.(ff2.x) by A14,FUNCT_2:15;
        g12.x = I.(f12.x) by A15,FUNCT_2:15
        .= I.(ff1.x + ff2.x) by LOPBAN_1:35;
        hence g12.x = g1.x + g2.x by A16,A17,VECTSP_1:def 20;
      end;
      hence thesis by LOPBAN_1:35;
    end;

    for f be Point of R_NormSpace_of_BoundedLinearOperators(X,Y),
        a be Real
    holds L.(a * f) = a * L.f
    proof
      let f be Point of R_NormSpace_of_BoundedLinearOperators(X,Y),
          a be Real;
      reconsider f1 = f, af = a * f as Lipschitzian LinearOperator of X,Y
        by LOPBAN_1:def 9;

      A18: L.f = I * f by A5;
      A19: L.(a * f) = I * (a * f) by A5;
      set g = L.f, ag = L.(a * f);
      for t be VECTOR of X holds ag.t = a * g.t
      proof
        let t be VECTOR of X;
        A20: g.t = I.(f1.t) by A18,FUNCT_2:15;
        ag.t = I.(af.t) by A19,FUNCT_2:15
        .= I.(a * f.t) by LOPBAN_1:36;
        hence ag.t = a * g.t by A20,LOPBAN_1:def 5;
      end;
      hence thesis by LOPBAN_1:36;
    end;
    then reconsider L as LinearOperator of
      R_NormSpace_of_BoundedLinearOperators(X,Y),
      R_NormSpace_of_BoundedLinearOperators(X,Z)
      by A12,LOPBAN_1:def 5,VECTSP_1:def 20;

    A21: for f be Element of R_NormSpace_of_BoundedLinearOperators(X,Y)
         holds ||.L.f.|| = ||.f.||
    proof
      let f be Point of R_NormSpace_of_BoundedLinearOperators(X,Y);
      reconsider f1 = f as Lipschitzian LinearOperator of X,Y
        by LOPBAN_1:def 9;
      reconsider g = L.f as Lipschitzian LinearOperator of X,Z
        by LOPBAN_1:def 9;
      A22: ||.f.||
       = BoundedLinearOperatorsNorm(X,Y).f by NORMSP_0:def 1
      .= upper_bound PreNorms(f1) by LOPBAN_1:30;

      A23: ||.L.f.||
       = BoundedLinearOperatorsNorm(X,Z).g by NORMSP_0:def 1
      .= upper_bound PreNorms(g) by LOPBAN_1:30;

      for z be object holds z in PreNorms(f1) iff z in PreNorms(g)
      proof
        let z be object;
        hereby
          assume z in PreNorms(f1);
          then consider x be VECTOR of X such that
          A24: z = ||.f1.x.|| & ||.x.|| <= 1;
          g = I * f by A5;

          then
          ||.g.x.||
           = ||.I.(f1.x).|| by FUNCT_2:15
          .= ||.f1.x.|| by A1,NDIFF_7:7;

          hence z in PreNorms(g) by A24;
        end;

        assume z in PreNorms(g);
        then consider x be VECTOR of X such that
        A25: z = ||.g.x.|| & ||.x.|| <= 1;

        ||.g.x.||
         = ||.(I * f1).x.|| by A5
        .= ||.I.(f1.x).|| by FUNCT_2:15
        .= ||.f1.x.|| by NDIFF_7:7,A1;

        hence z in PreNorms(f1) by A25;
      end;
      hence thesis by A22,A23,TARSKI:2;
    end;
    then L is isometric by NDIFF_7:7;
    then reconsider L as Lipschitzian LinearOperator of
      R_NormSpace_of_BoundedLinearOperators(X,Y),
      R_NormSpace_of_BoundedLinearOperators(X,Z);
    take L;
    thus thesis by A5,A10,A21,NDIFF_7:7,A6,FUNCT_2:10,FUNCT_2:19;
  end;
