reserve x,y for object,X,Y for set,
  D for non empty set,
  i,j,k,l,m,n,m9,n9 for Nat,
  i0,j0,n0,m0 for non zero Nat,
  K for Field,
  a,b for Element of K,
  p for FinSequence of K,
  M for Matrix of n,K;
reserve A for (Matrix of D),
  A9 for Matrix of n9,m9,D,
  M9 for Matrix of n9, m9,K,
  nt,nt1,nt2 for Element of n-tuples_on NAT,
  mt,mt1 for Element of m -tuples_on NAT,
  M for Matrix of K;

theorem Th36:
  for nt,nt1,nt9,nt19 be Element of n-tuples_on NAT st rng nt =
rng nt9 & rng nt1 = rng nt19 holds Det Segm(M,nt,nt1) = Det Segm(M,nt9,nt19) or
  Det Segm(M,nt,nt1) = -Det Segm(M,nt9,nt19)
proof
  let nt,nt1,nt9,nt19 be Element of n-tuples_on NAT such that
A1: rng nt=rng nt9 and
A2: rng nt1=rng nt19;
  set S19=Segm(M,nt,nt19);
  set S9=Segm(M,nt9,nt19);
  set S=Segm(M,nt,nt1);
  per cases;
  suppose
A3: not nt is one-to-one or not nt1 is one-to-one;
    then
A4: Det S=0.K by Th27,Th31;
    not nt9 is one-to-one or not nt19 is one-to-one by A1,A2,A3,Lm1;
    hence thesis by A4,Th27,Th31;
  end;
  suppose
A5: nt is one-to-one & nt1 is one-to-one;
    then nt19 is one-to-one by A2,Lm1;
    then consider perm1 be Permutation of Seg n such that
A6: nt1 = nt19 * perm1 by A2,A5,Th32;
    nt9 is one-to-one by A1,A5,Lm1;
    then consider perm be Permutation of Seg n such that
A7: nt = nt9 * perm by A1,A5,Th32;
    reconsider perm,perm1 as Element of Permutations n by MATRIX_1:def 12;
    per cases;
    suppose
A8:   perm1 is even;
      Det S = -(Det S19,perm1) by A6,Th35;
      then
A9:   Det S=Det S19 by A8,MATRIX_1:def 16;
      Det S19 = -(Det S9,perm) by A7,Th35;
      hence thesis by A9,MATRIX_1:def 16;
    end;
    suppose
A10:  perm1 is odd;
      Det S19 = -(Det S9,perm) by A7,Th35;
      then
A11:  Det S19=Det S9 or Det S19=-Det S9 by MATRIX_1:def 16;
      Det S = -(Det S19,perm1) by A6,Th35;
      then Det S=-Det S19 by A10,MATRIX_1:def 16;
      then Det S=-Det S9 or Det S = 0.K + --Det S9 by A11,RLVECT_1:def 4;
      then Det S=-Det S9 or Det S = 0.K -(-Det S9);
      then Det S=-Det S9 or Det S +(- Det S9) =0.K by VECTSP_2:2;
      hence thesis by VECTSP_1:19;
    end;
  end;
end;
