reserve i, j, m, n, k for Nat,
  x, y for set,
  K for Field,
  a,a1 for Element of K;
reserve V1,V2,V3 for finite-dimensional VectSp of K,
  f for Function of V1,V2,

  b1,b19 for OrdBasis of V1,
  B1 for FinSequence of V1,
  b2 for OrdBasis of V2,
  B2 for FinSequence of V2,

  B3 for FinSequence of V3,
  v1,w1 for Element of V1,
  R,R1,R2 for FinSequence of V1,
  p,p1,p2 for FinSequence of K;

theorem Th36:
  for M be Matrix of len b1,len b2,K holds AutMt(Mx2Tran(M,b1,b2), b1,b2) = M
proof
  let M be Matrix of len b1,len b2,K;
  set MX=Mx2Tran(M,b1,b2);
  set A=AutMt(MX,b1,b2);
  set ONE=1.(K,len b1);
A1: len M=len b1 by MATRIX_0:25;
A2: len A=len b1 by MATRIX_0:25;
A3: len ONE=len b1 by MATRIX_0:24;
  now
    let i such that
A4: 1<=i & i<=len M;
A5: i in Seg len b1 by A1,A4;
A6: i in dom ONE by A1,A3,A4,FINSEQ_3:25;
    reconsider Ai = A/.i as FinSequence of K by FINSEQ_1:def 11;
A7: i in dom b1 by A1,A4,FINSEQ_3:25;
    then A/.i=MX.(b1/.i) |--b2 by MATRLIN:def 8;
    then LineVec2Mx(Ai qua FinSequence of K) = LineVec2Mx(b1/.i|--b1) * M
             by A1,A4,Th32
      .= LineVec2Mx(Line(ONE,i))*M by A7,Th19
      .= LineVec2Mx(Line(ONE*M,i)) by A1,A6,Th35,MATRIX_0:24
      .= LineVec2Mx(Line(M,i)) by A1,MATRIXR2:68;
    then
A8: Ai = Line(LineVec2Mx(Line(M,i)),1) by MATRIX15:25
      .= Line(M,i) by MATRIX15:25
      .= M.i by A5,MATRIX_0:52;
    i in dom A by A1,A2,A4,FINSEQ_3:25;
    hence M.i = A.i by A8,PARTFUN1:def 6;
  end;
  hence thesis by A2,FINSEQ_1:14,MATRIX_0:25;
end;
