
theorem Th36:
  for X be non empty set, S be SigmaField of X, f be PartFunc of X
,ExtREAL, A be Element of S, F,G be Finite_Sep_Sequence of S, a be FinSequence
of ExtREAL st dom F = dom G & (for n be Nat st n in dom F holds G.n = F.n /\ A)
  & F,a are_Re-presentation_of f holds G,a are_Re-presentation_of f|A
proof
  let X be non empty set;
  let S be SigmaField of X;
  let f be PartFunc of X,ExtREAL;
  let A be Element of S;
  let F,G be Finite_Sep_Sequence of S;
  let a be FinSequence of ExtREAL;
  assume that
A1: dom F = dom G and
A2: for n be Nat st n in dom F holds G.n = F.n /\ A and
A3: F,a are_Re-presentation_of f;
A4: dom G = dom a by A1,A3,MESFUNC3:def 1;
  now
    let v be object;
    assume v in union rng G;
    then consider C be set such that
A5: v in C and
A6: C in rng G by TARSKI:def 4;
    consider k be object such that
A7: k in dom G and
A8: C = G.k by A6,FUNCT_1:def 3;
A9: F.k in rng F by A1,A7,FUNCT_1:3;
A10: G.k = F.k /\ A by A1,A2,A7;
    then v in F.k by A5,A8,XBOOLE_0:def 4;
    then v in union rng F by A9,TARSKI:def 4;
    then
A11: v in dom f by A3,MESFUNC3:def 1;
    v in A by A5,A8,A10,XBOOLE_0:def 4;
    then v in dom f /\ A by A11,XBOOLE_0:def 4;
    hence v in dom(f|A) by RELAT_1:61;
  end;
  then
A12: union rng G c= dom(f|A);
A13: for k be Nat st k in dom G
  for x be object st x in G.k holds (f|A).x = a.k
  proof
A14: for k be Nat st k in dom G for x be set st x in G.k holds f.x = a.k
    proof
      let k be Nat;
      assume
A15:  k in dom G;
      let x be set;
      assume x in G.k;
      then x in F.k /\ A by A1,A2,A15;
      then x in F.k by XBOOLE_0:def 4;
      hence thesis by A1,A3,A15,MESFUNC3:def 1;
    end;
    let k be Nat;
    assume
A16: k in dom G;
    let x be object;
    assume
A17: x in G.k;
    G.k in rng G by A16,FUNCT_1:3;
    then x in union rng G by A17,TARSKI:def 4;
    then (f|A).x = f.x by A12,FUNCT_1:47;
    hence thesis by A16,A17,A14;
  end;
  now
    let v be object;
    assume v in dom(f|A);
    then
A18: v in dom f /\ A by RELAT_1:61;
    then v in dom f by XBOOLE_0:def 4;
    then v in union rng F by A3,MESFUNC3:def 1;
    then consider C be set such that
A19: v in C and
A20: C in rng F by TARSKI:def 4;
    consider k be Nat such that
A21: k in dom F and
A22: C = F.k by A20,FINSEQ_2:10;
A23: G.k = F.k /\ A by A2,A21;
A24: G.k in rng G by A1,A21,FUNCT_1:3;
    v in A by A18,XBOOLE_0:def 4;
    then v in F.k /\ A by A19,A22,XBOOLE_0:def 4;
    hence v in union rng G by A23,A24,TARSKI:def 4;
  end;
  then dom(f|A) c= union rng G;
  then dom(f|A) = union rng G by A12;
  hence thesis by A4,A13,MESFUNC3:def 1;
end;
