reserve x,y,z for set;

theorem
  for S being non void Signature for X being ManySortedSet of the
  carrier of S st for s being SortSymbol of S st X.s = {} ex o being OperSymbol
  of S st the_result_sort_of o = s & the_arity_of o = {} holds Free(S, X) is
  non-empty
proof
  let C be non void Signature;
  let X be ManySortedSet of the carrier of C such that
A1: for s being SortSymbol of C st X.s = {} ex o being OperSymbol of C
  st the_result_sort_of o = s & the_arity_of o = {};
  now
    assume {} in rng the Sorts of Free(C, X);
    then consider s being object such that
A2: s in dom the Sorts of Free(C, X) and
A3: {} = (the Sorts of Free(C, X)).s by FUNCT_1:def 3;
    reconsider s as SortSymbol of C by A2;
    set x = the Element of X.s;
    per cases;
    suppose
      X.s = {};
      then
      ex m being OperSymbol of C st the_result_sort_of m = s & the_arity_of
      m = {} by A1;
      hence contradiction by A3,Th5;
    end;
    suppose
      X.s <> {};
      then root-tree [x, s] in (the Sorts of Free(C, X)).s by Th4;
      hence contradiction by A3;
    end;
  end;
  then the Sorts of Free(C, X) is non-empty by RELAT_1:def 9;
  hence thesis by MSUALG_1:def 3;
end;
