reserve A,B,a,b,c,d,e,f,g,h for set;

theorem
  for G being RelStr, H1,H2 being non empty RelStr, x being Element of
  H1, y being Element of H2 st G = sum_of(H1,H2) holds not [x,y] in the
  InternalRel of ComplRelStr G
proof
  let G being RelStr,H1,H2 being non empty RelStr, x being Element of H1, y
  being Element of H2;
  set cH1 = the carrier of H1, cH2 = the carrier of H2, IH1 = the InternalRel
  of H1, IH2 = the InternalRel of H2;
  [x,y] in [:cH1,cH2:] \/ [:cH2,cH1:] by XBOOLE_0:def 3;
  then [x,y] in IH2 \/ ([:cH1,cH2:] \/ [:cH2,cH1:]) by XBOOLE_0:def 3;
  then [x,y] in IH1 \/ (IH2 \/ ([:cH1,cH2:] \/ [:cH2,cH1:])) by XBOOLE_0:def 3;
  then [x,y] in IH1 \/ (IH2 \/ [:cH1,cH2:] \/ [:cH2,cH1:]) by XBOOLE_1:4;
  then
A1: [x,y] in IH1 \/ IH2 \/ [:cH1,cH2:] \/ [:cH2,cH1:] by XBOOLE_1:113;
  assume G = sum_of(H1,H2);
  then
A2: [x,y] in the InternalRel of G by A1,NECKLA_2:def 3;
  not [x,y] in the InternalRel of ComplRelStr G
  proof
    assume not thesis;
    then [x,y] in (the InternalRel of G) /\ the InternalRel of ComplRelStr G
    by A2,XBOOLE_0:def 4;
    then (the InternalRel of G) meets the InternalRel of ComplRelStr G;
    hence contradiction by Th12;
  end;
  hence thesis;
end;
